liborcus-0.7.1-r2.ebuild: USE tools

liborcus-0.7.1-r2.ebuild (text/plain), 1021 bytes, created by Matthew Millar on 2016-01-15 03:06:33 UTC

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5

EGIT_REPO_URI="git://gitlab.com/orcus/orcus.git"

[[ ${PV} == 9999 ]] && GITECLASS="git-2 autotools"
inherit eutils ${GITECLASS}
unset GITECLASS

DESCRIPTION="Standalone file import filter library for spreadsheet documents"
HOMEPAGE="https://gitlab.com/orcus/orcus"
[[ ${PV} == 9999 ]] || SRC_URI="http://kohei.us/files/orcus/src/${P}.tar.xz"

LICENSE="MIT"
SLOT="0"
[[ ${PV} == 9999 ]] || \
KEYWORDS="amd64 ~arm ~ppc x86"

IUSE="minimal static-libs tools"

RDEPEND="
	>=dev-libs/boost-1.51.0:=
	!minimal? ( >=dev-libs/libixion-0.9:= )
	sys-libs/zlib:=
"
DEPEND="${RDEPEND}
	>=dev-util/mdds-0.8.1
"

src_prepare() {
	[[ ${PV} == 9999 ]] && eautoreconf
}

src_configure() {
	econf \
		--disable-werror \
		$(usex minimal '--disable-spreadsheet-model' '--enable-spreadsheet-model' ) \
		$(use_enable static-libs static) \
		$(use_with tools)
}

src_install() {
	default

	prune_libtool_files --all
}