ebuild for fvwm-crystal-3.4.0

fvwm-crystal-3.4.0.ebuild (text/plain), 2.17 KB, created by Dominique Michel on 2016-01-03 16:36:56 UTC

# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="5"

PYTHON_COMPAT=( python2_7 )
inherit subversion eutils readme.gentoo python-r1 user

DESCRIPTION="Configurable and full featured FVWM theme, with lots of transparency and freedesktop compatible menu"
HOMEPAGE="http://fvwm-crystal.org/"

LICENSE="GPL-3"
SLOT="0"
if [[ "${PV}" = "9999" ]]; then
	ESVN_REPO_URI="svn://svn.code.sf.net/p/fvwm-crystal/code"
	SRC_URI=""
	KEYWORDS=""
else
	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
fi

REQUIRED_USE="${PYTHON_REQUIRED_USE}"
IUSE="+amixer jack +pm-utils +xdg"

RDEPEND="${PYTHON_DEPS}
	>=x11-wm/fvwm-2.5.26[png]
	|| ( media-gfx/imagemagick media-gfx/graphicsmagick[imagemagick] )
	|| ( >=x11-misc/stalonetray-0.6.2-r2 x11-misc/trayer )
	|| ( x11-misc/hsetroot media-gfx/feh )
	sys-apps/sed
	sys-devel/bc
	virtual/awk
	x11-apps/xwd
	xdg? ( x11-misc/xdg-user-dirs )
	pm-utils? ( sys-power/pm-utils )
	amixer? ( media-sound/alsa-utils )
	jack? ( media-sound/jack-audio-connection-kit )"

DISABLE_AUTOFORMATTING="true"
DOC_CONTENTS="After installation, execute following commands:
	$ cp -r \"${EPREFIX}/usr/share/${PN}/addons/Xresources\" ~/.Xresources
	$ cp -r \"${EPREFIX}/usr/share/${PN}/addons/Xsession\" ~/.xinitrc

Many applications can extend functionality of fvwm-crystal.
They are listed in \"${EPREFIX}/usr/share/doc/${PF}/INSTALL.bz2*\"

To be able to use the exit menu, each user using ${PN}
must be in the group fvwm-crystal.
You can do that as root with:
	useradd -G fvwm-crystal <user_name>
and log out and in again.
"

if [[ "${PV}" = "9999" ]]; then
	S="${WORKDIR}/${PN}"
fi

pkg_setup() {
	enewgroup fvwm-crystal
}

src_unpack() {
	if [[ "${PV}" = "9999" ]]; then
		subversion_src_unpack
	else
		unpack ${A}
	fi
}

src_install() {
	emake \
		DESTDIR="${ED}" \
		docdir="${EPREFIX}/usr/share/doc/${PF}" \
		prefix="${EPREFIX}/usr" \
		install

	# GNU license is  globally into  the portage tree
	rm -vf "${ED}/usr/share/doc/${PF}"/LICENSE

	python_replicate_script \
		"${ED}/usr/bin/${PN}".{apps,wallpaper} \
		"${ED}/usr/share/${PN}"/fvwm/scripts/FvwmMPD/*.py
	readme.gentoo_create_doc
}