minitube-2.5.1.ebuild

minitube-2.5.1.ebuild (text/plain), 2.73 KB, created by i.Dark_Templar on 2015-12-21 06:24:41 UTC

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5
PLOCALES="ar ca ca_ES da de_DE el en es es_AR es_ES fi fi_FI fr he_IL hr hu
ia it jv nl pl pl_PL pt_BR ro ru sk sl tr zh_CN"
PLOCALE_BACKUP="en"

inherit l10n qmake-utils

DESCRIPTION="Qt5 YouTube Client"
HOMEPAGE="http://flavio.tordini.org/minitube"
SRC_URI="https://github.com/flaviotordini/${PN}/archive/${PV}.tar.gz ->
${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug download gstreamer"

DEPEND="dev-qt/qtgui:5[accessibility]
	dev-qt/qtwidgets:5
	dev-qt/qtdbus:5
	dev-qt/qtsql:5
	dev-qt/qtsingleapplication[qt5(+),X]
	media-libs/phonon[gstreamer?,qt5]
	gstreamer? (
		media-plugins/gst-plugins-soup:0.10
		media-plugins/gst-plugins-ffmpeg:0.10
		media-plugins/gst-plugins-faac:0.10
		media-plugins/gst-plugins-faad:0.10
		media-plugins/gst-plugins-theora
	)
"
RDEPEND="${DEPEND}"

DOCS="AUTHORS CHANGES TODO"

pkg_pretend() {
	if [[ -z ${MINITUBE_GOOGLE_API_KEY} ]]; then
		eerror ""
		eerror "Since version 2.4, you need to generate a Google API Key to use"
		eerror "with this application. Please head over to"
		eerror "https://console.developers.google.com/ and"
		eerror "https://github.com/flaviotordini/minitube/blob/master/README.md"
		eerror "for more information. Once you have generated your key,"
		eerror "please export it to your environment ie :"
		eerror "'export MINITUBE_GOOGLE_API_KEY=\"YourAPIKeyHere\""
		eerror "and then try to merge this package again"
		eerror ""
		die "MINITUBE_GOOGLE_API_KEY env variable not defined!"
	fi
}

src_prepare() {
	#455976
	epatch "${FILESDIR}"/${P}-disable-updates.patch

	eqmake5

	# Remove unneeded translations
	local trans=
	for x in $(l10n_get_locales); do
		trans+="${x}.ts "
	done
	if [[ -n ${trans} ]]; then
		sed -i -e "/^TRANSLATIONS/s/+=.*/+=${trans}/" locale/locale.pri || die
	fi
	sed -i \
		's|include(src/qtsingleapplication/qtsingleapplication.pri)|CONFIG += qtsingleapplication|g' \
		${PN}.pro || die "Failed to unbundle qtsingleapplication"
	# Enable video downloads. Bug #491344
	use download && { echo "DEFINES += APP_DOWNLOADS" >> ${PN}.pro; }
	echo "DEFINES += APP_GOOGLE_API_KEY=${MINITUBE_GOOGLE_API_KEY}" >> ${PN}.pro
}

src_install() {
	emake INSTALL_ROOT="${D}" install
	einstalldocs
	newicon images/app.png minitube.png
}

pkg_postinst() {
	if use download; then
		elog "You activated the 'download' USE flag. This allows you to"
		elog "download videos from youtube, which might violate the youtube"
		elog "terms-of-service (TOS) in some legislations. If downloading"
		elog "youtube-videos is not allowed in your legislation, please"
		elog "disable the 'download' use flag. For details on the youtube TOS,"
		elog "see http://www.youtube.com/t/terms"
	fi
}