fontconfig-ultimate-9999.ebuild

fontconfig-ultimate-9999.ebuild (text/plain), 3.65 KB, created by cristiano04 on 2015-11-29 02:56:42 UTC

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5
EGIT_REPO_URI="https://github.com/bohoomil/fontconfig-ultimate.git"

inherit readme.gentoo git-2

DESCRIPTION="A set of rendering and font replacement rules for fontconfig-infinality"
HOMEPAGE="https://bohoomil.com/"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+fonts-ms +fonts-free fonts-extra"

RDEPEND="app-eselect/eselect-infinality
	app-eselect/eselect-lcdfilter
	media-libs/fontconfig-infinality
	media-libs/freetype:2[infinality]
	fonts-ms? (
		media-fonts/corefonts
		media-fonts/dejavu
		media-fonts/noto
		fonts-extra? (
			media-fonts/cantarell
			media-fonts/croscorefonts
			media-fonts/droid
			media-fonts/font-bh-75dpi
			media-fonts/font-bh-100dpi
			media-fonts/paratype
		)
	)
	fonts-free? (
		media-fonts/dejavu
		media-fonts/noto
		media-fonts/liberation-fonts
		media-fonts/heuristica
		fonts-extra? (
			media-fonts/cantarell
			media-fonts/croscorefonts
			media-fonts/droid
			media-fonts/font-bh-ttf
			media-fonts/libertine
			media-fonts/paratype
			media-fonts/urw-fonts
		)
	)"

DISABLE_AUTOFORMATTING="1"
DOC_CONTENTS="1. Disable all rules but '52-infinality.conf' using eselect fontconfig;
2. Enable one of \"ultimate\" presets using eselect infinality;
3. Select ultimate 'lcdfilter' settings using eselect lcdfilter;
4. Modify USE_STYLE in infinality-settings.sh if you want to tinker with the ft filter."

BLACKLIST="43-wqy-zenhei-sharp.conf"

src_prepare() {
	# Generate lcdfilter config
	echo -e "### FONTCONFIG ULTIMATE STYLE ###\n" \
	> "${T}"/ultimate || die

	sed --quiet \
		-e '/INFINALITY_FT_FILTER_PARAMS=/p' \
		freetype/infinality-settings.sh \
	| sed --quiet \
		-e "${infinality_style} s/[ \t]*export[ \t]*//p" \
	>> "${T}"/ultimate
	assert

	sed --quiet \
		-e '/INFINALITY_FT_FILTER_PARAMS/ d' \
		-e 's/^[ \t]*export[ \t]*INFINALITY_FT/INFINALITY_FT/p' \
		freetype/infinality-settings.sh \
	>> "${T}"/ultimate || die
}

src_install() {
	insinto /etc/fonts/infinality/conf.src.ultimate
	doins conf.d.infinality/*.conf
	doins fontconfig_patches/{ms,free,combi}/*.conf

	# Cut a list of default .conf files out of Makefile.am
	local default_configs config
	default_configs=$(sed --quiet \
		-e ':again' \
		-e '/\\$/ N' \
		-e 's/\\\n/ /' \
		-e 't again' \
		-e 's/^CONF_LINKS =//p' \
		conf.d.infinality/Makefile.am) || die

	cd fontconfig_patches/ms || die
	for config in ${default_configs} *.conf; do
		dosym ../../conf.src.ultimate/"${config}" \
			/etc/fonts/infinality/styles.conf.avail/ultimate-ms/"${config}"
	done
	cd ../../fontconfig_patches/free || die
	for config in ${default_configs} *.conf; do
		dosym ../../conf.src.ultimate/"${config}" \
			/etc/fonts/infinality/styles.conf.avail/ultimate-free/"${config}"
	done
	cd ../../fontconfig_patches/combi || die
	for config in ${default_configs} *.conf; do
		dosym ../../conf.src.ultimate/"${config}" \
			/etc/fonts/infinality/styles.conf.avail/ultimate-combi/"${config}"
	done
	cd "${S}"

	insinto /usr/share/eselect-lcdfilter/env.d
	doins "${T}"/ultimate

	insinto /etc/profile.d
	doins freetype/infinality-settings.sh

	dodoc -r doc/fontconfig-infinality-ultimate/fontconfig-global doc/fontconfig-infinality-ultimate/fontconfig-user


	readme.gentoo_create_doc
	
	ewarn "As of version 2.6.2-1, fontconfig-ultimate comes with the 'ultimate3' rendering style enabled internally by default.\n It is still possible to use the optional 'infinality-settings.sh' script to switch between additional built-in rendering schemes and create custom ones if necessary.\n Once modified, '/etc/profile.d/infinality-settings.sh' needs to be copied to '/etc/X11/xinit/xinitrc.d/infinality-settings.sh'."
}