# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-rpg/vegastrike/vegastrike-0.4.1.ebuild,v 1.13 2004/06/24 23:17:11 agriffis Exp $

inherit flag-o-matic eutils games cvs

DESCRIPTION="A 3D space simulator that allows you to trade and bounty hunt"
HOMEPAGE="http://vegastrike.sourceforge.net/"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86 ~ppc"
IUSE="stencil-buffer debug"

RDEPEND="virtual/x11
	virtual/glu
	virtual/glut
	virtual/opengl
	media-libs/libsdl
	media-libs/jpeg
	media-libs/libpng
	dev-libs/expat
	media-libs/openal
	media-libs/sdl-mixer
	=x11-libs/gtk+-1*"
DEPEND="${RDEPEND}
	dev-lang/perl
	>=sys-devel/autoconf-2.58"

ECVS_SERVER="cvs.sourceforge.net:/cvsroot/vegastrike"
ECVS_BRANCH="vegastrike_0_4_2"
S="${WORKDIR}"

src_unpack() {
	cd ${S}
	local cvs=${ECVS_TOP_DIR}

	if [ ! -d "${cvs}/vegastrike" ]; then
		ECVS_MODULE="vegastrike"
		cvs_src_unpack || die "Fetching vegastrike failed"
	fi
	if ([ ! -d "${cvs}/data" ] && [ ! -d "${cvs}/data4.x" ]); then
		ECVS_MODULE="data4.x"
		cvs_src_unpack || die "Fetching data failed"
	fi
	if [ ! -d "${cvs}/vssetup" ]; then
		ECVS_MODULE="vssetup"
		cvs_src_unpack || die "Fetching vssetup failed"
	fi
	einfo "Copying data to work directory..."
	cp -a ${cvs}/{vegastrike,data{,4.x},vssetup} ${S} >&/dev/null

	mv data4.x data >&/dev/null
	cd ${S}/data

	if [ ! -d "${cvs}/music" ]; then
		ECVS_MODULE="music"
		cvs_src_unpack || die "Fetching music failed"
	fi
	einfo "Copying game music to work directory..."
	cp -a ${cvs}/music ${S}/data >&/dev/null

	# We don't need any windows stuff
	rm -rf bin
	# Clean up data dir
	find -name CVS -type d -exec rm -rf '{}' \; >&/dev/null
	find -name '*~' -type f -exec rm -f '{}' \; >&/dev/null
	# Converts vegastrike.ico into png if we've got imagemagick
	convert vegastrike.ico png:vegastrike.png >&/dev/null

	# Sort out directory references
	sed -i \
		-e "s!/usr/local/share/doc!/usr/share/doc!" \
		-e "s!/usr/local/share/vegastrike!${GAMES_DATADIR}/vegastrike!" \
		-e "s!/usr/games/vegastrike!${GAMES_DATADIR}/vegastrike!" \
		-e "s!/usr/local/bin!${GAMES_BINDIR}!" \
		-e "s!/usr/local/lib/man!/usr/share/man!" \
		documentation/vegastrike.1 \
		|| die "sed data/documentation/vegastrike.1 failed"

	cd ${S}/vegastrike
	sed -i \
		-e "s!/usr/games/vegastrike!${GAMES_DATADIR}/vegastrike!" \
		-e "s!/usr/local/bin!${GAMES_BINDIR}!" \
		launcher/saveinterface.cpp \
		|| die "sed launcher/saveinterface.cpp failed"
	sed -i \
		"s!/usr/local/share/vegastrike!${GAMES_DATADIR}/vegastrike!" \
		src/common/common.cpp \
		|| die "sed src/common/common.cpp failed"
	sed -i \
		"s!/usr/share/local/vegastrike!${GAMES_DATADIR}/vegastrike!" \
		src/vsfilesystem.cpp \
		|| die "sed src/filesys.cpp failed"
	sed -i \
		-e '/^SUBDIRS =/s:tools::' \
		Makefile.am \
		|| die "sed Makefile.am failed"
	aclocal || die "aclocal failed"
	WANT_AUTOCONF=2.5 autoconf || die "autoconf failed"
	autoheader
	automake -a || die "automake failed"
}

src_compile() {
	cd ${S}/vegastrike
	egamesconf \
		--disable-dependency-tracking \
		$(use_enable debug) \
		$(use_enable stencil-buffer) \
		|| die "egamesconf failed"
	emake || die "emake failed"
	cd ${S}/vssetup/src/
	perl ./build || die "perl build failed"
}

src_install() {
	cd ${S}
	cat << EOF > vsinstall
#!/bin/sh
(
mkdir $HOME/.vegastrike 2> /dev/null
cd $HOME/.vegastrike
if [ -f save.4.x.txt ] ; then
	touch save.4.x.txt
else
	echo "default"> save.4.x.txt
fi
cp ${GAMES_DATADIR}/vegastrike/data/setup.config .
cp ${GAMES_DATADIR}/vegastrike/data/.vegastrike/*.m3u .
cp ${GAMES_DATADIR}/vegastrike/data/vegastrike.config .
${GAMES_BINDIR}/vssetup
)
echo "If you wish to have your own music edit ~/.vegastrike/*.m3u"
echo "Each playlist represents a place or situation in Vega Strike"
exit 0
EOF
	dogamesbin \
		vegastrike/src/vegastrike \
		vegastrike/launcher/vslauncher \
		vsinstall \
		|| die "dogamesbin failed"
	newgamesbin vssetup/src/bin/setup vssetup || die "newgamesbin failed"
	cp -rf vegastrike/src/networking/soundserver data/ || die "cp failed"

	doman data/documentation/*.1
	dodoc data/documentation/*.txt

	dodir "${GAMES_DATADIR}/${PN}"
	cp -r data/ "${D}/${GAMES_DATADIR}/${PN}/" || die "cp failed (data)"
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	einfo "run vsinstall to setup your account"
	einfo "then run vslauncher to start Vega Strike"
}