mediawiki-1.3.5.ebuild

mediawiki-1.3.5.ebuild (text/plain), 6.09 KB, created by Ævar Arnfjörð Bjarmason on 2004-10-11 13:10:59 UTC

# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU Free Documentation License and the GNU General Public License v2
# $Header: /home/cvsroot/gentoo-x86/net-www/mediawiki/mediawiki-20030829 aplank Exp $

inherit webapp

DESCRIPTION="MediaWiki is a Wiki server software that software that runs http://www.wikipedia.org amongst other things"
HOMEPAGE="http://wikipedia.sourceforge.net/"
SRC_URI="mirror://sourceforge/wikipedia/${P}.tar.gz"
RESTRICT="nomirror"
LICENSE="GPL-2"
KEYWORDS="~x86"
# SLOT="0"  Cannot be set: it collides with webapp.eclass

# imagemagick enables the image upload functionality.
# tetex enables the math support that requires Objective Caml
# to build.
# Actually requires PHP >= 4.1.2 but there's no really good
# way to indicate this in a web server independent way.
#
IUSE="imagemagick tetex"
DEPEND=" tetex? ( >=dev-lang/ocaml-3.0.6 ) "
RDEPEND="
        >=dev-db/mysql-3.23
        virtual/php
        tetex? ( app-text/tetex )
        imagemagick? ( media-gfx/imagemagick )"


src_compile() {
        # Only required if tetex USE flag is set
        #
        if use tetex; then
                einfo "Compiling math support"
                cd math
                emake
        else
                einfo "Nothing to compile"
        fi
}


src_install() {
        webapp_src_preinst

        # Copy the app's main files excluding math support and docs
        #
        local directories='config images includes languages languages/wikipedia
                        maintenance maintenance/archives maintenance/postgresql
                        stylesheets stylesheets/davinci stylesheets/images
                        stylesheets/mono stylesheets/monobook
                        stylesheets/myskin templates
                        PHPTAL-NP-0.7.0 PHPTAL-NP-0.7.0/libs
                        PHPTAL-NP-0.7.0/libs/Algo PHPTAL-NP-0.7.0/libs/PHPTAL
                        PHPTAL-NP-0.7.0/libs/PHPTAL/Attribute
                        PHPTAL-NP-0.7.0/libs/PHPTAL/Attribute/I18N
                        PHPTAL-NP-0.7.0/libs/PHPTAL/Attribute/METAL
                        PHPTAL-NP-0.7.0/libs/PHPTAL/Attribute/PHPTAL
                        PHPTAL-NP-0.7.0/libs/PHPTAL/Attribute/TAL
                        PHPTAL-NP-0.7.0/libs/Types'

        einfo "Installing main files"
        insinto ${MY_HTDOCSDIR}
        doins *.php *.inc *.phtml
        for directory in ${directories}; do
                dodir ${MY_HTDOCSDIR}/${directory}
                insinto ${MY_HTDOCSDIR}/${directory}
                doins ${directory}/*
        done

        # NOTE that doc files go into /usr/share/doc as normal; they do NOT
        # get installed per vhost!
        #
        dodoc COPYING INSTALL README RELEASE-NOTES
        dodoc docs/*.doc
        docinto php-memcached
        dodoc docs/php-memcached/*

        # If imagemagick is enabled then setup for image upload.
        # We ensure the directory is prepared for writing.  The post-
        # install instructions guide the user to enable the feature.
        #
        if use imagemagick; then
                webapp_serverowned ${MY_HTDOCSDIR}/images
        fi

        # If we've enabled tetex, install math support.
        # We ensure the directories are prepared for writing.  The post-
        # install instructions guide the user to enable the feature.
        #
        if use tetex; then
                einfo "Installing math support"
                dodir ${MY_HTDOCSDIR}/math
                exeinto ${MY_HTDOCSDIR}/math
                doexe math/texvc

                # Docs
                #
                docinto math
                dodoc math/README math/TODO

                # Working directories.  Server writeable.
                #
                dodir ${MY_HTDOCSDIR}/images/math
                webapp_serverowned ${MY_HTDOCSDIR}/images/math
                dodir ${MY_HTDOCSDIR}/images/tmp
                webapp_serverowned ${MY_HTDOCSDIR}/images/tmp
        fi

        # And some basic post install notes for webapp-config
        #
        webapp_postinst_txt en ${FILESDIR}/postintall-en.txt

        webapp_src_install
}

pkg_postinst() {
	einfo
	einfo "Completing setup:"
	einfo
	einfo "To complete installation cd into the MediaWiki install location, but"
	einfo "make sure to start mysql first with:"
	einfo
	einfo "$ /etc/init.d/mysql start"
	einfo
	einfo "$ cd /var/www/localhost/htdocs/mediawiki/"
	einfo
	einfo "Then temporarily make the MediaWiki /config directory writable"
	einfo "to the  user the web server is running as. The quickest way is "
	einfo "to make  the directory world writable.  For example:"
	einfo
	einfo "$ chmod a+w config"
	einfo 
	einfo "Then access it, for example:"
	einfo
	einfo "lynx http://localhost/mediawiki/config/"
	einfo 
	einfo "After setup move the newly created LocalSettings.hp from the config/"
	einfo "directory to the main mediawiki directory, for example:"
	einfo  
	einfo "$ mv config/LocalSettings.php ."
	ewarn
	ewarn "Remember to restore safe permissions to the MediaWiki config/ and"
	ewarn "LocalSettings.php (which contains clear-text passwords)."
	ewarn "chmod a-w config"
	ewarn "chmod ug=r,o=  LocalSettings.php"
	ewarn "chown root:apache LocalSettings.php"
	ewarn
	einfo "After these steps MediaWiki should be accesable at"
	einfo "http://localhost/mediawiki/"
	einfo 
	einfo "Enabling Optional Features:"
	einfo
	einfo "If you wish to enable image uploads then you must manually edit the"
	einfo "LocalSettings.php file to uncomment the \$wgDisableUploads line.  If" 
	einfo "MediaWiki was built with the imagemagick USE flag the directory"
	einfo "permissions are correct, otherwise you must install ImageMagick and" 
	einfo "also adjust permissions on the images directory to allow the server"
	einfo "to write.  For example:"
	einfo 
	einfo "$ chown apache:apache /var/www/localhost/htdocs/mediawiki/images"
	einfo
	einfo "If you wish to enable the math support then you must manually edit" 
	einfo "the LocalSettings.php file to uncomment the \$wgUseTeX line."
	einfo "Mediawiki must have been built with the tetex USE flag enabled or the"
	einfo "necessary support executable will not be present."
	einfo
}