tomatoes-1.5.ebuild

tomatoes-1.5.ebuild (text/plain), 1.90 KB, created by Ali Sabil on 2004-10-10 07:24:23 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

DESCRIPTION="How many tomatoes can you smash in ten short minutes?"
HOMEPAGE="http://tomatoes.sourceforge.net/about.html"
SRC_URI="mirror://sourceforge/tomatoes/tomatoes-linux-src-${PV}.tar.bz2
		 mirror://sourceforge/tomatoes/tomatoes-linux-${PV}.tar.bz2"

LICENSE="ZLIB"
SLOT="0"
KEYWORDS="x86"
IUSE=""

DEPEND="virtual/opengl
	>=media-libs/libsdl-1.2.7
	>=media-libs/fmod-3.73"

src_unpack() {
	unpack ${A}
	cd "${S}"
	sed -i \
		-e '/^CC/d' \
		-e '/^MARCH/d' \
		-e "/^CFLAGS/s/=.*$/= ${CFLAGS} \$(SDL_FLAGS)/" \
		makefile \
		|| die "sed failed"

	sed -i \
		-e "s:MPKDIR = ./:MPKDIR = ${GAMES_DATADIR}/${PN}/:" \
		makefile \
		|| die "sed failed"
	
	sed -i \
		-e "s:MUSICDIR = ./music/:MUSICDIR = ${GAMES_DATADIR}/${PN}/music/:" \
		makefile \
		|| die "sed failed"

	sed -i \
		-e "s:HISCOREDIR = ./:HISCOREDIR = ${GAMES_STATEDIR}/${PN}/:" \
		makefile \
		|| die "sed failed"

	sed -i \
		-e "s:CONFIGDIR = ./:CONFIGDIR = ${GAMES_STATEDIR}/${PN}/:" \
		makefile \
		|| die "sed failed"

	sed -i \
		-e "s:OVERRIDEDIR = ./data/:OVERRIDEDIR = ${GAMES_DATADIR}/${PN}/data/:" \
		makefile \
		|| die "sed failed"
		

}

src_install() {
	dogamesbin tomatoes || die "dogamesbin failed"
	dodir "${GAMES_DATADIR}/${PN}" "${GAMES_STATEDIR}/${PN}"
	dodoc README README-src || die "failed to install docs"

	cp -r tomatoes.mpk music/ "${D}${GAMES_DATADIR}/${PN}" \
		|| die "failed to copy game data"

	insinto "${GAMES_STATEDIR}/${PN}/"
	insopts -m0660
	doins config.cfg || die "failed to copy game config"
	

	touch "${D}${GAMES_STATEDIR}/${PN}/hiscore.lst" || die "touch failed"
	fperms 660 "${GAMES_STATEDIR}/${PN}/hiscore.lst"

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	echo
	einfo "You can change the game settings by editing: "
	einfo "${GAMES_SYSCONFDIR}/tomatoes/config.cfg"
	echo
}