From 1f5f6db45c6aeb468834ff38f02f602d485207bf Mon Sep 17 00:00:00 2001
From: Julian Ospald <hasufell@gentoo.org>
Date: Fri, 2 Oct 2015 17:36:45 +0200
Subject: [PATCH] dev-qt/qtnetwork: add libressl support

---
 dev-qt/qtnetwork/qtnetwork-5.4.2-r1.ebuild | 54 ++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 dev-qt/qtnetwork/qtnetwork-5.4.2-r1.ebuild

diff --git a/dev-qt/qtnetwork/qtnetwork-5.4.2-r1.ebuild b/dev-qt/qtnetwork/qtnetwork-5.4.2-r1.ebuild
new file mode 100644
index 0000000..f04d44a
--- /dev/null
+++ b/dev-qt/qtnetwork/qtnetwork-5.4.2-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="Network abstraction library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc64 ~x86"
+fi
+
+IUSE="bindist connman libressl networkmanager +ssl"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	>=sys-libs/zlib-1.2.5
+	connman? ( ~dev-qt/qtdbus-${PV} )
+	networkmanager? ( ~dev-qt/qtdbus-${PV} )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0[bindist=] )
+		libressl? ( dev-libs/libressl )
+	)
+"
+RDEPEND="${DEPEND}
+	connman? ( net-misc/connman )
+	networkmanager? ( net-misc/networkmanager )
+"
+
+QT5_TARGET_SUBDIRS=(
+	src/network
+	src/plugins/bearer/generic
+)
+
+QT5_GENTOO_CONFIG=(
+	ssl::SSL
+	ssl::OPENSSL
+	ssl:openssl-linked:LINKED_OPENSSL
+)
+
+pkg_setup() {
+	use connman && QT5_TARGET_SUBDIRS+=(src/plugins/bearer/connman)
+	use networkmanager && QT5_TARGET_SUBDIRS+=(src/plugins/bearer/networkmanager)
+}
+
+src_configure() {
+	local myconf=(
+		$(use connman || use networkmanager && echo -dbus-linked)
+		$(use ssl && echo -openssl-linked)
+	)
+	qt5-build_src_configure
+}
-- 
2.5.3