itext-2.1.7.ebuild

itext-2.1.7.ebuild (text/plain), 1.88 KB, created by Karsten Merkle on 2015-08-24 11:09:04 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI="5"

JAVA_PKG_IUSE="doc source"

inherit java-pkg-2 java-ant-2

MY_PV=$(replace_all_version_separators '_' )
MY_P="${PN/it/iT}_${MY_PV}"
ASIANJAR="iTextAsian.jar"
ASIANCMAPSJAR="iTextAsianCmaps.jar"

DESCRIPTION="A Java library that generate documents in the Portable Document Format (PDF) and/or HTML"
HOMEPAGE="http://www.lowagie.com/iText/"
SRC_URI="https://github.com/itext/itextpdf/archive/${MY_P}.tar.gz"

LICENSE="MPL-1.1"
SLOT="2.1"
KEYWORDS="amd64 ppc ppc64 x86 ~amd64-linux ~x86-linux"
IUSE="cjk rtf"

BCV="1.38"

COMMON_DEPEND="
	dev-java/bcmail:${BCV}
	dev-java/bcprov:${BCV}
	dev-java/bctsp:${BCV}"
RDEPEND="${COMMON_DEPEND}
	>=virtual/jre-1.5"
DEPEND="${COMMON_DEPEND}
	>=virtual/jdk-1.5
	app-arch/unzip"

S="${WORKDIR}/itextpdf-${MY_P}"

EANT_BUILD_XML="${S}/src/build.xml"

java_prepare() {
    einfo "Removing bundled jars..."
	mv ${S}/lib/${ASIANJAR} ${S}/lib/${ASIANJAR}.bak
	mv ${S}/lib/${ASIANCMAPSJAR} ${S}/lib/${ASIANCMAPSJAR}.bak
	find -name "*.jar" -type f | xargs rm -v
	mv ${S}/lib/${ASIANJAR}.bak ${S}/lib/${ASIANJAR}
	mv ${S}/lib/${ASIANCMAPSJAR}.bak ${S}/lib/${ASIANCMAPSJAR}

	java-pkg_jar-from --into ${S}/lib bcprov-${BCV}  bcprov.jar bcprov-jdk14-138.jar
	java-pkg_jar-from --into ${S}/lib bcmail-${BCV} bcmail.jar bcmail-jdk14-138.jar
	java-pkg_jar-from --into ${S}/lib bctsp-${BCV} bctsp.jar bctsp-jdk14-138.jar
	java-ant_bsfix_files ${EANT_BUILD_XML} || die "failed to rewrite build xml files"
}

src_compile() {
	java-pkg-2_src_compile \
		$(use rtf && echo "jar.rtf")
}

src_install() {
	java-pkg_dojar lib/iText.jar
	use rtf && java-pkg_dojar lib/iText-rtf.jar
	if use cjk; then
		java-pkg_dojar "${DISTDIR}/${ASIANJAR}"
		java-pkg_dojar "${DISTDIR}/${ASIANCMAPSJAR}"
	fi

	use source && java-pkg_dosrc src/core/com
	use doc && java-pkg_dojavadoc build/docs
}