# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id: 2d241b1f868c5fa171dc2b4e48b31e56b5d40e06 $

EAPI="5"
inherit eutils flag-o-matic toolchain-funcs multilib-minimal

DESCRIPTION="console display library"
HOMEPAGE="http://www.gnu.org/software/ncurses/ http://dickey.his.com/ncurses/"
SRC_URI="mirror://gnu/ncurses/${P}.tar.gz"

LICENSE="MIT"
SLOT="5.9"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
IUSE="debug tinfo trace unicode"

DEPEND=""
#	berkdb? ( sys-libs/db )"
RDEPEND="${DEPEND}
	!=sys-libs/ncurses-5*:5
	!<x11-terms/rxvt-unicode-9.06-r3
	abi_x86_32? (
		!<=app-emulation/emul-linux-x86-baselibs-20130224-r12
		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
	)"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-5.8-gfbsd.patch
	epatch "${FILESDIR}"/${PN}-5.7-nongnu.patch
	epatch "${FILESDIR}"/${PN}-5.9-pkg-config.patch
	epatch "${FILESDIR}"/${P}-no-I-usr-include.patch #522586
	epatch "${FILESDIR}"/${P}-gcc-5.patch #545114
}

src_configure() {
	unset TERMINFO #115036
	tc-export_build_env BUILD_{CC,CPP}
	BUILD_CPPFLAGS+=" -D_GNU_SOURCE" #214642

	multilib-minimal_src_configure
}

multilib_src_configure() {
	do_configure narrowc
	use unicode && do_configure widec --enable-widec
}

do_configure() {
	ECONF_SOURCE=${S}

	mkdir "${BUILD_DIR}"-$1
	cd "${BUILD_DIR}"-$1 || die
	shift

	local conf=(
		# We need the basic terminfo files in /etc, bug #37026.  We will
		# add '--with-terminfo-dirs' and then populate /etc/terminfo in
		# src_install() ...
		--with-terminfo-dirs="${EPREFIX}/etc/terminfo:${EPREFIX}/usr/share/terminfo"

		# Disabled until #245417 is sorted out.
		#$(use_with berkdb hashed-db)

		# Now the rest of the various standard flags.
		--with-shared
		--without-normal
		--without-hashed-db
		--without-ada
		--without-cxx
		--without-cxx-binding
		--without-debug
		--without-profile
		# GPM is now built against the wrong ncurses
		--without-gpm
		--disable-termcap
		--enable-symlinks
		--with-rcs-ids
		--enable-const
		--enable-colorfgbg
		--enable-echo
		--enable-warnings
		$(use_with debug assertions)
		$(use_enable !debug leaks)
		$(use_with debug expanded)
		$(use_with !debug macros)
		$(use_with trace)
		$(use_with tinfo termlib)

		# The chtype/mmask-t settings below are to retain ABI compat
		# with ncurses-5.4 so dont change em !
		--with-chtype=long
		--with-mmask-t=long
		--disable-ext-colors
		--disable-ext-mouse
		--without-pthread
		--without-reentrant
	)

	# Force bash until upstream rebuilds the configure script with a newer
	# version of autotools. #545532
	CONFIG_SHELL=/bin/bash econf "${conf[@]}" "$@"
}

multilib_src_compile() {
	make_flags="PROGS= "
	do_compile narrowc
	use unicode && do_compile widec
}

do_compile() {
	cd "${BUILD_DIR}"-$1 || die

	# A little hack to fix parallel builds ... they break when
	# generating sources so if we generate the sources first (in
	# non-parallel), we can then build the rest of the package
	# in parallel.  This is not really a perf hit since the source
	# generation is quite small.
	emake -j1 sources
	emake ${make_flags}
}

multilib_src_install() {
	local libs=( form menu ncurses panel )
	use tinfo && libs+=( tinfo )

	cd "${BUILD_DIR}"-narrowc || die
	for lib in "${libs[@]}"; do
		dolib.so lib/lib${lib}$(get_libname 5.9)
		dosym lib${lib}$(get_libname 5.9) /usr/$(get_libdir)/lib${lib}$(get_libname 5)
	done

	if use unicode ; then
		cd "${BUILD_DIR}"-widec || die
		for lib in "${libs[@]}"; do
			dolib.so lib/lib${lib}w$(get_libname 5.9)
			dosym lib${lib}w$(get_libname 5.9) /usr/$(get_libdir)/lib${lib}w$(get_libname 5)
		done
	fi
}

# Override default to not install documentation
multilib_src_install_all() { :; }