ebuild for racket 6.2

racket-6.2.ebuild (text/plain), 1.92 KB, created by khaelin on 2015-07-02 19:24:29 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-scheme/racket/racket-6.0.1.ebuild,v 1.2 2014/08/10 21:25:26 slyfox Exp $

EAPI="5"

# for live ebuilds uncomment inherit git-2, comment SRC_URI and empty KEYWORDS

inherit eutils pax-utils
#inherit git-2

DESCRIPTION="Racket is a general-purpose programming language with strong support for domain-specific languages"
HOMEPAGE="http://racket-lang.org/"
SRC_URI="minimal? ( http://mirror.racket-lang.org/installers/${PV}/${PN}-minimal-${PV}-src-builtpkgs.tgz ) !minimal? ( http://mirror.racket-lang.org/installers/${PV}/${P}-src-builtpkgs.tgz )"
EGIT_REPO_URI="https://github.com/plt/racket.git"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="doc +futures +jit minimal +places +threads +X"
REQUIRED_USE="futures? ( jit )"

# see bug 426316: racket/draw (which depends on cairo) is sometimes used in compile-time code or when rendering documentation
RDEPEND="dev-db/sqlite:3 x11-libs/cairo[X?] virtual/libffi"
DEPEND="${RDEPEND}"

EGIT_SOURCEDIR="${WORKDIR}/${P}"
S="${WORKDIR}/${P}/src"

src_prepare() {
	#remove bundled libraries
	rm -rf foreign/libffi/
}

src_configure() {
# according to vapier, we should use the bundled libtool
# such that we don't preclude cross-compile. Thus don't use
# --enable-lt=/usr/bin/libtool
	econf \
		$(use_enable X gracket) \
		$(use_enable doc docs) \
		--enable-shared \
		$(use_enable jit) \
		--enable-foreign \
		$(use_enable places) \
		$(use_enable futures) \
		$(use_enable threads pthread)
}

src_compile() {
	if use jit; then
		pushd racket
		emake cgc
		pax-mark m .libs/racketcgc
		emake 3m
		pax-mark m .libs/racket3m
		popd
	fi
	emake
}

src_install() {
	#racket now comes with desktop files, but DESTDIR is mishandled
	for f in /usr/share/applications/{drracket,slideshow}.desktop; do
		sed -ie "s|${D}||" "${D}/${f}"
	done

	emake DESTDIR="${D}" install
}