freecol-0.11.3.ebuild

freecol-0.11.3.ebuild (text/plain), 2.05 KB, created by Thomas Sachau on 2015-05-18 10:18:09 UTC

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/freecol/freecol-0.10.7.ebuild,v 1.3 2015/02/25 15:52:06 ago Exp $

EAPI=5
inherit base eutils java-pkg-2 java-ant-2 games

DESCRIPTION="An open source clone of the game Colonization"
HOMEPAGE="http://www.freecol.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}-src.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE=""

COMMON_DEP="dev-java/jsr173
	dev-java/wstx:3.2
	dev-java/commons-cli:1
	dev-java/cortado
	dev-java/miglayout
	dev-java/jorbis"

DEPEND=">=virtual/jdk-1.7
	app-arch/unzip
	${COMMON_DEP}"
RDEPEND=">=virtual/jre-1.7
	${COMMON_DEP}"

S=${WORKDIR}/${PN}

#PATCHES=( "${FILESDIR}"/${P}-gentoo.patch )

java_prepare() {
	rm -r jars
	sed -i  -e 's:${basedir}/${miglayout-swing.jar}:${miglayout.jar}:g' \
		-e 's:${basedir}/${cli.jar}:${cli.jar}:g' \
		-e 's:${basedir}/${cortado.jar}:${cortado.jar}:g' \
		-e 's:${basedir}/jars/jorbis-0.0.15.jar:${jorbis.jar}:g' \
		-e 's:manifestclasspath :manifestclasspath maxParentLevels="50" :g' \
		"${S}"/build.xml || die
}

src_prepare() {
	base_src_prepare
	java-pkg-2_src_prepare
}

src_configure() {
	java-ant-2_src_configure
}

src_compile() {
	EANT_BUILD_TARGET=package
	EANT_EXTRA_ARGS="
		-Dstax.jar=$(java-pkg_getjars jsr173)
		-Dwoodstox.jar=$(java-pkg_getjars wstx-3.2)
		-Dcli.jar=$(java-pkg_getjars commons-cli-1)
		-Dmiglayout.jar=$(java-pkg_getjars miglayout)
		-Dcortado.jar=$(java-pkg_getjars cortado)
		-Djorbis.jar=$(java-pkg_getjars jorbis)
	"
	java-pkg-2_src_compile
}

src_install() {
	java-pkg_jarinto "${GAMES_DATADIR}"/${PN}
	java-pkg_dojar FreeCol.jar
	java-pkg_dolauncher ${PN} \
		-into "${GAMES_PREFIX}" \
		--pwd "${GAMES_DATADIR}"/${PN} \
		--jar FreeCol.jar \
		--java_args -Xmx512M
	insinto "${GAMES_DATADIR}"/${PN}
	doins -r data schema splash.jpg
	doicon ${PN}.xpm
	make_desktop_entry ${PN} FreeCol
	dodoc README
	prepgamesdirs
}

pkg_setup() {
	games_pkg_setup
	java-pkg-2_pkg_setup
}

pkg_preinst() {
	games_pkg_preinst
	java-pkg-2_pkg_preinst
}