# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/tlsdate/tlsdate-0.0.12-r1.ebuild,v 1.1 2015/01/03 00:29:06 hanno Exp $

EAPI="4"

inherit autotools vcs-snapshot user eutils

DESCRIPTION="Update local time over HTTPS"
HOMEPAGE="https://github.com/ioerror/tlsdate"
SRC_URI="https://github.com/ioerror/tlsdate/tarball/${P} -> ${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="amd64 arm x86"
IUSE="dbus mbedtls +seccomp static-libs"

DEPEND="mbedtls? ( net-libs/mbedtls )
        !mbedtls? ( dev-libs/openssl )
	dev-libs/libevent
	dbus? ( sys-apps/dbus )"
RDEPEND="${DEPEND}"

src_prepare() {
	# Use Google servers by default rather than a random German site.
	# They provide round robin DNS and local servers automatically.
	sed -i \
		-e 's:www.ptb.de:www.google.com:' \
		etc/tlsdated.conf \
		src/tlsdate.h || die

	epatch "${FILESDIR}/${P}-uclibc.patch"
	epatch "${FILESDIR}/${P}-mbedtls-v2.patch"

	eautoreconf
}

src_configure() {
	econf \
		$(use_enable dbus) \
		$(use_enable seccomp seccomp-filter) \
		--disable-hardened-checks \
		$(use_with mbedtls polarssl) \
		--with-unpriv-user=tlsdate \
		--with-unpriv-group=tlsdate
}

src_install() {
	default

	# only install cert required for www.google.com
	rm "${ED}"/etc/tlsdate/ca-roots/tlsdate-ca-roots.conf || die #446426
	dosym "${EPREFIX}"/etc/ssl/certs/Equifax_Secure_CA.pem \
		/etc/tlsdate/ca-roots/tlsdate-ca-roots.conf

	newinitd "${FILESDIR}"/tlsdated.rc tlsdated
	newconfd "${FILESDIR}"/tlsdated.confd tlsdated
	newinitd "${FILESDIR}"/tlsdate.rc tlsdate
	newconfd "${FILESDIR}"/tlsdate.confd tlsdate

	insinto /etc/dbus-1/system.d/
	doins dbus/org.torproject.tlsdate.conf

	use static-libs || \
		find "${ED}"/usr '(' -name '*.la' -o -name '*.a' ')' -delete

	rm -rf "${ED}/usr/share/doc/${PN}"
}

pkg_preinst() {
	enewgroup tlsdate 124
	enewuser tlsdate 124 -1 /dev/null tlsdate
}