updated ebuild script necessary for current version of ShowEQ.

showeq-5.0.0.15.ebuild (text/plain), 2.22 KB, created by Erik Bunce on 2004-09-24 16:14:06 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $


inherit base games kde-functions

DESCRIPTION="Realtime packet analyzer for Everquest"
HOMEPAGE="http://seq.sourceforge.net"
SRC_URI="mirror://sourceforge/seq/showeq-${PV}.tar.bz2"
# SRC_URI="http://www.doomed.to/showeq/showeq-${PV}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86 ~amd64"
IUSE="debug"

RDEPEND="virtual/x11
	virtual/libc
	sys-libs/zlib
	media-libs/libpng
	>=net-libs/libpcap-0.6.2
	>=sys-libs/gdbm-1.8.0"

# possible virtual
# RDEPEND="${RDEPEND} virtual/seq-maps"

DEPEND="${RDEPEND}
	>=sys-devel/gcc-3.0.5
	>=sys-apps/sed-4"

need-qt 3.1

src_unpack() {
	unpack ${A}
	cd ${S}

	sed -i -e "s:\$USE_PROFILE_C\":\$USE_PROFILE_C \$CFLAGS\":" \
		-e "s:\$USE_PROFILE_CXX:\$USE_PROFILE_CXX \$CXXFLAGS:" \
		configure
}

myegamesconf() {
	if [ -x ./configure ] ; then
		myconf="--prefix=${GAMES_PREFIX} \
			--host=${CHOST} \
			--mandir=/usr/share/man \
			--infodir=/usr/share/info \
			--datadir=${GAMES_DATADIR} \
			--sysconfdir=${GAMES_SYSCONFDIR} \
			--localstatedir=${GAMES_STATEDIR} \
			--disable-dependency-tracking \
			--with-qt-dir=${QTDIR}"

		if use debug ; then
			myconf="$myconf --enable-debug=yes --disable-inlines"
		else
			myconf="$myconf --disable-debug"
		fi

		echo \
		./configure \
			${myconf} \
			CXXFLAGS="${CXXFLAGS}" CFLAGS="${CFLAGS}" \
			"$@"
		./configure \
			${myconf} \
			CXXFLAGS="${CXXFLAGS}" CFLAGS="${CFLAGS}" \
			"$@" || die "myegamesconf failed"
	else
		die "no configure script found"
	fi
}

src_compile() {
	cd ${S}

	# fix the sandbox errors "can't writ to .kde or .qt" problems.
	# this is a fake homedir that is writeable under the sandbox, so that the build process
	# can do anything it wants with it.
	REALHOME="$HOME"
	mkdir -p $T/fakehome/.qt
	addwrite "${QTDIR}/etc/settings"
	[ -d "$REALHOME/.ccache" ] && ln -sf "$REALHOME/.ccache" "$HOME/"	

	myegamesconf            || die
	emake                 || die "emake failed"
}

src_install() {
	egamesinstall  || die
	doman showeq.1 || die "doman failed"
	dodoc AUTHORS BUGS ChangeLog FAQ INSTALL NEWS README* ROADMAP TODO doc/*.{doc,txt} || \
				      die "dodoc failed"
	dohtml doc/*   || die "dohtml failed"
	prepgamesdirs
}