miniupnpc-1.9.20150206.ebuild

miniupnpc-1.9.20150206.ebuild (text/plain), 1.48 KB, created by Nikoli on 2015-04-26 17:12:06 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/miniupnpc/miniupnpc-1.8.ebuild,v 1.10 2014/05/02 12:53:17 jer Exp $

EAPI=5

inherit eutils multilib toolchain-funcs

DESCRIPTION="UPnP client library and a simple UPnP client"
HOMEPAGE="http://miniupnp.free.fr/"
#SRC_URI="http://miniupnp.free.fr/files/${P}.tar.gz"
# https://github.com/miniupnp/miniupnp/issues/111
MY_COMMIT="e280c3dd3abb7fd636c06503d0f7041256717387"
SRC_URI="https://github.com/miniupnp/miniupnp/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"

LICENSE="BSD"
SLOT="0/12"
KEYWORDS="~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="ipv6 kernel_linux static-libs"

# Tests hang trying to kill server, bug #409349
#RESTRICT="test"

RDEPEND=""
DEPEND="kernel_linux? ( sys-apps/lsb-release sys-apps/which )"

S="${WORKDIR}/miniupnp-${MY_COMMIT}/${PN}"

src_prepare() {
	epatch_user

	if ! use static-libs; then
		sed -i \
			-e '/FILESTOINSTALL =/s/ $(LIBRARY)//' \
			-e '/$(INSTALL) -m 644 $(LIBRARY) $(INSTALLDIRLIB)/d' \
			Makefile || die
	fi
}

# Upstream cmake causes more trouble than it fixes,
# so we'll just stay with the Makefile for now.

src_compile() {
	tc-export CC AR
	emake upnpc-shared $(use static-libs && echo upnpc-static)
}

src_test() {
	emake -j1 HAVE_IPV6=$(usex ipv6 yes no) check
}

src_install() {
	emake \
		PREFIX="${D}" \
		INSTALLDIRLIB="${D}usr/$(get_libdir)" \
		install

	dodoc README Changelog.txt
}