netpanzer-0.8.4.ebuild

netpanzer-0.8.4.ebuild (text/plain), 1.56 KB, created by Mr. Bones. (RETIRED) on 2015-04-18 03:30:14 UTC

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/netpanzer/netpanzer-0.8.2.ebuild,v 1.11 2015/02/18 19:08:13 mr_bones_ Exp $

EAPI=5
inherit eutils scons-utils toolchain-funcs games

DESCRIPTION="Fast-action multiplayer strategic network game"
HOMEPAGE="http://www.netpanzer.info/"
SRC_URI="http://sourceforge.net/code-snapshots/svn/n/ne/netpanzerfp/code/netpanzerfp-code-1450-tags-netpanzer.zip -> ${P}.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="dedicated"

RDEPEND="dedicated? ( app-misc/screen )
	media-libs/libsdl[sound,video]
	media-libs/sdl-mixer
	media-libs/sdl-image
	dev-games/physfs[zip]"
DEPEND=${RDEPEND}

S=${WORKDIR}/netpanzerfp-code-1450-tags-netpanzer/${PV}

src_prepare() {
	sed \
		-e "s:@GENTOO_BINDIR@:${GAMES_BINDIR}:" \
		"${FILESDIR}"/${PN}-ded > "${T}"/${PN}-ded || die
	sed \
		-e "s:GAMES_USER_DED:${GAMES_USER_DED}:" \
		-e "s:GENTOO_DIR:${GAMES_BINDIR}:" \
		"${FILESDIR}"/${PN}.rc > "${T}"/${PN} || die
	epatch \
		"${FILESDIR}/${P}-gcc47.patch" \
		"${FILESDIR}/${P}-scons-blows.patch"
}

src_compile() {
	escons \
		CC="$(tc-getCC)" \
		CXX="$(tc-getCXX)" \
		datadir="${GAMES_DATADIR}/${PN}"
}

src_install() {
	dogamesbin ${PN}
	insinto "${GAMES_DATADIR}/${PN}"
	doins -r cache/ maps/ pics/ powerups/ scripts/ sound/ units/ wads/

	if use dedicated ; then
		doinitd "${T}"/${PN}
		insinto /etc
		doins "${FILESDIR}"/${PN}-ded.ini
		dogamesbin "${T}"/${PN}-ded
	fi

	doicon ${PN}.png
	make_desktop_entry ${PN} NetPanzer
	prepgamesdirs
}