freecol-0.11.3.ebuild

freecol-0.11.3.ebuild (text/plain), 1.76 KB, created by Mr. Bones. (RETIRED) on 2015-04-14 17:57:25 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/freecol/freecol-0.10.7.ebuild,v 1.1 2013/02/05 00:20:46 hasufell Exp $

EAPI=5
JAVA_ANT_ENCODING=UTF-8
inherit base eutils java-pkg-2 java-ant-2 games

DESCRIPTION="An open source clone of the game Colonization"
HOMEPAGE="http://www.freecol.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}-src.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

COMMON_DEP="dev-java/commons-cli:1
	dev-java/cortado"

DEPEND=">=virtual/jdk-1.7
	app-arch/unzip
	${COMMON_DEP}"
RDEPEND=">=virtual/jre-1.7
	${COMMON_DEP}"

S=${WORKDIR}/${PN}

PATCHES=( "${FILESDIR}"/${P}-gentoo.patch )

java_prepare() {
	cd jars || die
	rm commons-cli-1.1.jar || die
	rm cortado-0.6.0.jar || die
	rm jogg-0.0.7.jar || die
	rm jorbis-0.0.15.jar || die
}

src_prepare() {
	base_src_prepare
	java-pkg-2_src_prepare
}

src_configure() {
	java-ant-2_src_configure
}

src_compile() {
	EANT_BUILD_TARGET=package
	EANT_EXTRA_ARGS="
		-Dcli.jar=$(java-pkg_getjars commons-cli-1)
		-Dcortado.jar=$(java-pkg_getjars cortado)
	"
	java-pkg-2_src_compile
}

src_install() {
	java-pkg_jarinto "${GAMES_DATADIR}"/${PN}/jars
	java-pkg_dojar jars/miglayout-swing-4.2.jar
	java-pkg_dojar jars/miglayout-core-4.2.jar
	java-pkg_jarinto "${GAMES_DATADIR}"/${PN}
	java-pkg_dojar FreeCol.jar
	java-pkg_dolauncher ${PN} \
		-into "${GAMES_PREFIX}" \
		--pwd "${GAMES_DATADIR}"/${PN} \
		--jar FreeCol.jar \
		--java_args -Xmx512M
	insinto "${GAMES_DATADIR}"/${PN}
	doins -r data schema splash.jpg
	doicon ${PN}.xpm
	make_desktop_entry ${PN} FreeCol
	dodoc README
	prepgamesdirs
}

pkg_setup() {
	games_pkg_setup
	java-pkg-2_pkg_setup
}

pkg_preinst() {
	games_pkg_preinst
	java-pkg-2_pkg_preinst
}