# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

# Solving bug #428018

EAPI="5"

GCONF_DEBUG="yes"
GNOME2_LA_PUNT="yes"

inherit eutils gnome2 versionator virtualx user pam

MATE_BRANCH="$(get_version_component_range 1-2)"

SRC_URI="https://github.com/linuxmint/mdm/archive/${PV}.tar.gz"
DESCRIPTION="Mint Display Manager"
HOMEPAGE="https://github.com/linuxmint/mdm"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 x86"

IUSE_LIBC="elibc_glibc"
IUSE="accessibility afs +consolekit systemd dmx ipv6 gnome-keyring pam remote selinux tcpd xinerama -scrollkeeper $IUSE_LIBC"

# webkit-gtk-2.6 dropped support for the 1.0 API
RDEPEND="!=gnome-base/gdm-2*
	>=dev-libs/glib-2.12:2
	=net-libs/webkit-gtk-2.4*
	>=x11-libs/gtk+-2.6:2
	>=x11-libs/pango-1.3
	>=gnome-base/libglade-2:2.0
	>=gnome-base/libgnomecanvas-2
	>=gnome-base/librsvg-1.1.1:2
	>=dev-libs/libxml2-2.4.12:2
	>=media-libs/libart_lgpl-2.3.11
	net-libs/webkit-gtk:2
	x11-libs/gksu
	x11-libs/libXi
	x11-libs/libXau
	x11-libs/libX11
	x11-libs/libXext
	x11-apps/sessreg
	xinerama? ( x11-libs/libXinerama )
	consolekit? (
		sys-auth/consolekit
		dev-libs/dbus-glib )
	accessibility? ( x11-libs/libXevie )
	afs? ( net-fs/openafs sys-libs/lwp )
	dmx? ( x11-libs/libdmx )
	gnome-keyring? ( gnome-base/gnome-keyring[pam] )
	pam? ( virtual/pam )
	!pam? ( elibc_glibc? ( sys-apps/shadow ) )
	remote? ( gnome-extra/zenity )
	selinux? ( sys-libs/libselinux )
	tcpd? ( >=sys-apps/tcp-wrappers-7.6 )
	>=x11-misc/xdg-utils-1.0.2-r3"
DEPEND="${RDEPEND}
	gnome-base/gnome-common
	dmx? ( x11-proto/dmxproto )
	xinerama? ( x11-proto/xineramaproto )
	app-text/docbook-xml-dtd:4.1.2
	sys-devel/gettext
	x11-proto/inputproto
	>=dev-util/intltool-0.35
	virtual/pkgconfig
	scrollkeeper? ( >=app-text/scrollkeeper-0.1.4 )
	>=app-text/gnome-doc-utils-0.3.2"

pkg_setup() {
	DOCS="AUTHORS ChangeLog NEWS README TODO"
	G2CONF="${G2CONF}
		--with-prefetch=no
		--sysconfdir=/etc/X11
		--localstatedir=/var
		--with-pam-prefix=/etc
		--disable-static
		SOUND_PROGRAM=/usr/bin/mdmplay
		$(use_enable ipv6)
		$(use_enable scrollkeeper)
		$(use_enable remote secureremote)
		$(use_with accessibility xevie)
		$(use_with systemd)
		$(use_with selinux)
		$(use_with tcpd tcp-wrappers)
		$(use_with xinerama)"

	if use pam; then
		G2CONF="${G2CONF} --enable-authentication-scheme=pam"
	else
		G2CONF="${G2CONF} --enable-console-helper=no"
		if use elibc_glibc ; then
			G2CONF="${G2CONF} --enable-authentication-scheme=shadow"
		else
			G2CONF="${G2CONF} --enable-authentication-scheme=crypt"
		fi
	fi

	enewgroup mdm
	enewuser mdm -1 -1 /var/lib/mdm mdm
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	# Theme emulator does not run on gtk3
	epatch "${FILESDIR}/mdm-theme-emulator.patch"
}

src_prepare() {
	if [[ ! -e configure ]] ; then
		./autogen.sh || die "autogen failed"
	fi

	# Fix intltoolize broken file, see upstream #577133
	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in

	gnome2_src_prepare
}

src_install() {
	gnome2_src_install

	# mdm-binary should be mdm to work with our init (#5598)
	rm -f "${D}/usr/sbin/mdm"
	dosym /usr/sbin/mdm-binary /usr/sbin/mdm

	# our x11's scripts point to /usr/bin/mdm
	dosym /usr/sbin/mdm-binary /usr/bin/mdm

	# log, etc.
	keepdir /var/log/mdm
	keepdir /var/mdm

	fowners root:mdm /var/mdm
	fperms 1770 /var/mdm

	# install XDG_DATA_DIRS mdm changes
	echo 'XDG_DATA_DIRS="/usr/share/mdm"' > 99xdg-mdm
	doenvd 99xdg-mdm

	# avoid file collision, bug #213118
	rm -f "${D}/usr/share/xsessions/gnome.desktop"

	# add a custom sound playing script (#248253)
	dobin "${FILESDIR}/mdmplay"

	# We replace the pam stuff by our own
	rm -rf "${D}/etc/pam.d"

	if use pam ; then
		local gentoodir="${WORKDIR}/gentoo"
		mkdir -p "${gentoodir}"

		cp -R "${FILESDIR}"/pam.d/* "${gentoodir}"
		use gnome-keyring && sed -i "s:#Keyring=::g" "${gentoodir}"/*

		dopamd "${gentoodir}"/*
		dopamsecurity console.apps "${FILESDIR}/security/console.apps/mdmsetup"
	fi

	# use graphical greeter local
	sed -i -e "s:#Greeter=/usr/libexec/mdmlogin:Greeter=/usr/libexec/mdmgreeter:" \
		"${D}"/usr/share/mdm/defaults.conf

	# list available users
	sed -i -e "s:^#MinimalUID=.*:MinimalUID=1000:" "${D}"/usr/share/mdm/defaults.conf
	sed -i -e "s:^#IncludeAll=.*:IncludeAll=true:" "${D}"/usr/share/mdm/defaults.conf

	# Fix old X11R6 paths
	sed -i -e "s:/usr/X11R6/bin:/usr/bin:" "${D}"/usr/share/mdm/defaults.conf

	# Use Clearlooks as default theme, bug #268496
	sed -i -e "s:#GtkTheme=Default:GtkTheme=Clearlooks:" "${D}"/usr/share/mdm/defaults.conf

	# Wait more before assuming Xserver is defunct, bug #378765
	sed -i -e "s:MdmXserverTimeout=10:MdmXserverTimeout=25:" "${D}"/usr/share/mdm/defaults.conf

	# Create a distro.conf for mdm see upstream bug #76
	cp "${D}"/usr/share/mdm/defaults.conf "${D}"/usr/share/mdm/distro.conf

}

pkg_postinst() {
	gnome2_pkg_postinst

	elog "To make MDM start at boot, edit /etc/conf.d/xdm"
	elog "and then execute 'rc-update add xdm default'."

	elog "MDM has changed the location of its configuration file.  Please"
	elog "edit /etc/X11/mdm/custom.conf.  The factory defaults are located"
	elog "at /usr/share/mdm/{defaults.conf,distro.conf,factory-defaults.conf}"

	elog "See README.install for more information about the change."

	if use gnome-keyring; then
		elog "For autologin to unlock your keyring, you need to set an empty"
		elog "password on your keyring. Use app-crypt/seahorse for that."
	fi

	if [ -f "/etc/X11/mdm/mdm.conf" ]; then
		elog "You had /etc/X11/mdm/mdm.conf which is the old configuration"
		elog "file.  It has been moved to /etc/X11/mdm/mdm-pre-gnome-2.16"
		mv /etc/X11/mdm/mdm.conf /etc/X11/mdm/mdm-pre-gnome-2.16
	fi

	# Soft restart, assumes Gentoo defaults for file locations
	# Do restart after mdm.conf move above
	FIFOFILE=/var/mdm/.mdmfifo
	PIDFILE=/var/run/mdm.pid

	if [ -w ${FIFOFILE} ] ; then
		if [ -f ${PIDFILE} ] ; then
			if kill -0 `cat ${PIDFILE}`; then
				(echo;echo SOFT_RESTART) >> ${FIFOFILE}
			fi
		fi
	fi
}

pkg_postrm() {
	gnome2_pkg_postrm

	if [ "$(rc-config list default | grep xdm)" != "" ] ; then
		elog "To remove MDM from startup please execute"
		elog "'rc-update del xdm default'"
	fi
}