[patch] ntlmaps-0.9.9.6-r4.ebuild

ntlmaps-0.9.9.6-r4.ebuild (text/plain), 1.54 KB, created by Ian Delaney (RETIRED) on 2015-04-01 03:32:25 UTC

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-proxy/ntlmaps/ntlmaps-0.9.9.6-r3.ebuild,v 1.1 2014/07/01 17:06:26 pacho Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 )

inherit python-single-r1 systemd user

DESCRIPTION="NTLM proxy Authentication against MS proxy/web server"
HOMEPAGE="http://ntlmaps.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~x86"

RDEPEND="${PYTHON_DEPS}"

REQUIRED_USE="${PYTHON_REQUIRED_USE}"

pkg_setup() {
	python-single-r1_pkg_setup

	enewgroup ntlmaps
	enewuser ntlmaps -1 -1 -1 ntlmaps
}

src_prepare() {
	epatch "${FILESDIR}/${P}-gentoo.patch"
	python_fix_shebang main.py

	sed -i -e 's/\r//' lib/*.py server.cfg doc/*.{txt,htm} || die 'Failed to convert line endings.'
}

src_install() {
	python_export PYTHON_SITEDIR

	# Bug #351305, prevent file collision.
	rm "${S}"/lib/utils.py

	insinto "${PYTHON_SITEDIR#${EPREFIX}}"
	doins lib/*.py
	python_optimize

	exeinto /usr/bin
	newexe main.py ntlmaps

	dodoc doc/{ENCRYPTION.txt,README.txt}
	insinto /usr/share/doc/${PF}/html
	doins doc/*.{gif,htm}

	insopts -m0640 -g ntlmaps
	insinto /etc/ntlmaps
	doins server.cfg
	newinitd "${FILESDIR}/ntlmaps.init" ntlmaps
	systemd_dounit "${FILESDIR}"/${PN}.service

	diropts -m 0770 -g ntlmaps
	keepdir /var/log/ntlmaps
}

pkg_postinst() {
	elog "The docs for ntlmaps come installed by default in"
	elog "a single 'htm' file in /usr/share/doc/${PF}/html"
}