New ebuild

octave-forge-2004.09.09.ebuild (text/plain), 1.82 KB, created by Federico Zenith on 2004-09-20 00:07:54 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="A collection of custom scripts, functions and extensions for GNU Octave"
HOMEPAGE="http://octave.sourceforge.net/"
SRC_URI="mirror://sourceforge/octave/${P}.tar.gz"

LICENSE="as-is, BSD, GPL-2"
KEYWORDS="~x86 ~ppc ~sparc amd64"
SLOT="0"
IUSE="ginac qhull"

RDEPEND="=app-sci/octave-2.1.58
	sys-libs/libtermcap-compat
	!amd64? ( ginac? ( app-sci/ginac ) )
	qhull? ( >=media-libs/qhull-3.1-r1 )"

DEPEND="${RDEPEND} 
	>=sys-apps/sed-4"


src_compile() {
	econf || die "econf failed"

	# The *XPATH variables need to be changed, or they will
	# cause Portage access violations. They cannot be easily set just using
	# arguments passed to ./configure (at least, they can not easily be set
	# correctly)
	einfo "Modifying paths..."
	
	for path in M O X ALTM ALTO; do
		sed -i "s|^\(${path}PATH = \)|\1${D}|" Makeconf || \
			die "failed to modify ${path}PATH"
	done

	sed -i "s|\(mandir = \)|\1${D}|" Makeconf && 
	sed -i "s|\(bindir = \)|\1${D}|" Makeconf || die "sed failed"
	
	einfo "done.\n"

	emake || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" install || die "install failed"

	# strip the fudged install paths
	sed -i "s|${D}||g" ${D}/usr/bin/mex || die "sed failed"

	dodoc AUTHORS COPYING* ChangeLog INDEX RELEASE-NOTES TODO
}

pkg_postinst() {
	einfo "If you do not have GiNaC and Qhull installed, octave-forge did not"
	einfo "compile itself with support for the geometry and symbolic math"
	einfo "extensions. If you would like these features, please emerge ginac"
	einfo "and/or qhull and then re-emerge octave-forge. Alternately, you can"
	einfo "specify USE='ginac qhull' and re-emerge octave-forge; in that case"
	einfo "the ebuild will automatically install the additional packages."
}