# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

inherit cmake-utils git-r3

DESCRIPTION="Tool to poke around in a Qt-application and also to manipulate the application to some extent"
HOMEPAGE="http://www.kdab.com/gammaray"
EGIT_REPO_URI="git://github.com/KDAB/GammaRay.git"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS=""

# The kde USE flag should enable all plugins that have something to do with KDE
IUSE="doc kde objectvisualizer pdf qml qt4 qt5 scriptenginedebugger svg test ui"
REQUIRED_USE="
	^^ ( qt4 qt5 )
	pdf? ( qt5 )
	svg? ( qt5 )
	qml? ( qt5 )
	scriptenginedebugger? ( qt5 )
"

RDEPEND="
	media-gfx/graphviz
	objectvisualizer? (	sci-libs/vtk )
	qt4? (
		dev-qt/qtgui:4
		dev-qt/qtwebkit:4

		kde? ( kde-base/kdelibs	)
		test? (	dev-qt/qttest:4	)
		ui? ( dev-qt/designer:4	)
	)
	qt5? (
		>=dev-qt/qtconcurrent-5.4.0
		>=dev-qt/qtgui-5.4.0
		>=dev-qt/qtnetwork-5.4.0
		>=dev-qt/qtwebkit-5.4.0
		>=dev-qt/qtwidgets-5.4.0
		>=dev-qt/qtxml-5.4.0

		kde? ( kde-frameworks/kcoreaddons:5	)
		pdf? ( >=dev-qt/qtprintsupport-5.4.0 )
		qml? ( >=dev-qt/qtdeclarative-5.4.0	)
		scriptenginedebugger? (	>=dev-qt/qtscript-5.4.0[scripttools] )
		svg? ( >=dev-qt/qtsvg-5.4.0	)
		test? (	>=dev-qt/qttest-5.4.0 )
		ui? ( dev-qt/designer:5 )
	)
"
DEPEND="
	${RDEPEND}
	doc? ( app-doc/doxygen )
"

src_configure() {
	local mycmakeargs="
		$(cmake-utils_use_find_package doc Doxygen)
		$(cmake-utils_use_find_package objectvisualizer VTK)
	"

	if use qt4; then
		mycmakeargs+="
			-DGAMMARAY_ENFORCE_QT4_BUILD=true
			$(cmake-utils_use_find_package kde KDE4)
			$(cmake-utils_use_find_package test QtTest)
			$(cmake-utils_use_find_package ui QtDesigner)
		"
	else
		mycmakeargs+="
			$(cmake-utils_use_find_package kde KF5CoreAddons)
			$(cmake-utils_use_find_package pdf Qt5PrintSupport)
			$(cmake-utils_use_find_package scriptenginedebugger Qt5ScriptTools)
			$(cmake-utils_use_find_package svg Qt5Svg)
			$(cmake-utils_use_find_package test Qt5Test)
			$(cmake-utils_use_find_package ui Qt5Designer)
		"
	fi

	cmake-utils_src_configure
}