youtube-dl-9999.ebuild

youtube-dl-9999.ebuild (text/plain), 1.95 KB, created by Leonardo Amaral on 2015-03-13 17:11:06 UTC

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

PYTHON_COMPAT=(python{2_7,3_3,3_4})
DISTUTILS_SINGLE_IMPL=true
inherit bash-completion-r1 distutils-r1 eutils git-2 python-single-r1

DESCRIPTION="Download videos from YouTube.com (and more sites...)"
HOMEPAGE="http://rg3.github.com/youtube-dl/"
SRC_URI=""
EGIT_REPO_URI="git://github.com/rg3/youtube-dl.git https://github.com/rg3/youtube-dl.git"

LICENSE="public-domain"
SLOT="0"
KEYWORDS=""
IUSE="offensive test"

DEPEND="
	dev-python/setuptools[${PYTHON_USEDEP}]
	test? ( dev-python/nose[coverage(+)] )
"

S="${WORKDIR}/youtube-dl"

src_prepare() {
	if ! use offensive; then
		sed -i -e "/__version__/s|'$|-gentoo_no_offensive_sites'|g" \
			youtube_dl/version.py || die
		# these have single line import statements
		local xxx=(
			alphaporno anysex behindkink drtuber empflix eporner eroprofile
			extremetube fourtube foxgay goshgay hellporno hentaistigma
			hornbunny keezmovies mofosex motherless pornhd pornotube
			pornoxo redtube sexykarma sexu sunporno slutload spankwire thisav
			tnaflix trutube tube8 vporn xbef xhamster xnxx xtube xvideos
			xxxymovies youjizz youporn
		)
		# these have multi-line import statements
		local mxxx=(
			pornhub
		)
		# do single line imports
		sed -i -e $( printf '/%s/d;' ${xxx[@]} ) youtube_dl/extractor/__init__.py || die
		# do multiple line imports
		sed -i -e $( printf '/%s/,/)/d;' ${mxxx[@]} ) youtube_dl/extractor/__init__.py || die

		rm $( printf 'youtube_dl/extractor/%s.py ' ${xxx[@]} ) \
			$( printf 'youtube_dl/extractor/%s.py ' ${mxxx[@]} ) \
			test/test_age_restriction.py || die
	fi
}

src_compile() {
	distutils-r1_src_compile
	emake -C docs man
	${PYTHON} devscripts/bash-completion.py
}

src_test() {
	emake test
}

src_install() {
	python_domodule youtube_dl
	dobin bin/${PN}
	dodoc README.md
	doman docs/_build/man/${PN}.1
	newbashcomp ${PN}.bash-completion ${PN}
	python_fix_shebang "${ED}"
}