tomatoes-1.0.ebuild

tomatoes-1.0.ebuild (text/plain), 1.81 KB, created by Greg Watson (linuxkrn) on 2004-09-18 11:58:12 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

DESCRIPTION="How many tomatoes can you smash in ten short minutes?"
HOMEPAGE="http://tomatoes.sourceforge.net/about.html"
SRC_URI="http://unc.dl.sourceforge.net/sourceforge/tomatoes/tomatoes-linux-src-${PV}.tar.bz2
		 http://unc.dl.sourceforge.net/sourceforge/tomatoes/tomatoes-linux-${PV}.tar.bz2"

LICENSE="ZLIB"
KEYWORDS="x86"
SLOT="0"
IUSE=""

DEPEND="virtual/opengl
	>=media-libs/libsdl-1.2.7
	>=media-libs/fmod-3.73"

src_unpack() {
	unpack ${A}
	cd "${S}"
	sed -i \
		-e '/^CC/d' \
		-e '/^MARCH/d' \
		-e "/^CFLAGS/s/=.*$/= ${CFLAGS} \$(SDL_FLAGS)/" \
		makefile || die "sed failed"

	sed -i \
		-e "s:./tomatoes.mpk:${GAMES_DATADIR}/${PN}/tomatoes.mpk:" \
		-e "s:./config.cfg:${GAMES_SYSCONFDIR}/${PN}/config.cfg:" \
		-e "s:./hiscore.lst:${GAMES_STATEDIR}/${PN}/hiscore.lst:" \
		src/init.cpp src/menu.cpp include/hiscore.h

}

src_install() {
	dogamesbin tomatoes || die "dogamesbin failed"
	dodir "${GAMES_DATADIR}/${PN}" || die "failed to create game data dir"
	dodoc README README-src || die "failed to install docs"

  	dodir "${GAMES_DATADIR}/tomatoes" || die "failed to create game data dir"
    cp -r tomatoes.mpk music/ "${D}${GAMES_DATADIR}/tomatoes" || die "failed to copy game data"
    insinto "${GAMES_SYSCONFDIR}/tomatoes"
    doins config.cfg || die "failed to copy game config"
	fperms 660 "${GAMES_SYSCONFDIR}/tomatoes/config.cfg"

	# hiscore
	dodir "${GAMES_STATEDIR}/${PN}"
	touch "${D}${GAMES_STATEDIR}/${PN}/hiscore.lst"
	fperms 660 "${GAMES_STATEDIR}/${PN}/hiscore.lst"

	prepgamesdirs
}

pkg_postinst() {
        einfo
        einfo "You can change the game settings by editing: "
        einfo "${GAMES_SYSCONFDIR}/tomatoes/config.cfg"
		einfo 
        games_pkg_postinst
}