suds-0.6.ebuild

suds-0.6.ebuild (text/plain), 1.26 KB, created by Per Pomsel on 2015-02-17 08:23:47 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="5"
PYTHON_COMPAT=( python{2_6,2_7,3_3} )

inherit distutils-r1

DESCRIPTION="Lightweight SOAP client"
HOMEPAGE="https://bitbucket.org/jurko/suds/ http://pypi.python.org/pypi/suds"
SRC_URI="https://bitbucket.org/jurko/suds/downloads/${PN}-jurko-${PV}.tar.bz2 -> ${P}.tar.bz2"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc test"

DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
	doc? ( dev-python/epydoc[$(python_gen_usedep 'python2*')] )
	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
RDEPEND=""

DOCS=( README.rst notes/{argument_parsing.rst,readme.txt,traversing_client_data.rst} )
S="${WORKDIR}/${PN}-jurko-${PV}"

# Req'd for install phase
DISTUTILS_IN_SOURCE_BUILD=1

REQUIRED_USE="doc? ( || ( $(python_gen_useflags 'python2*') ) )"

python_compile_all() {
	if use doc; then
		epydoc -n "Suds - ${DESCRIPTION}" -o doc suds || die
	fi
}

python_test() {
	esetup.py test
}

python_install_all() {
	use doc && local HTML_DOCS=( doc/. )
	distutils-r1_python_install_all
}

python_install() {
	# test folder makes for file collisions by the eclass
	rm -rf ./{tests,build/lib/tests}/ || die
	distutils-r1_python_install
}