AUX emacs-vcs-musl.patch 2344 SHA256 2e4072282384a42646e1beb50cc1354e24ceab67128e41ebb23549f2466545fe SHA512 d581f5c964d6ae3a2b31acb5c60469086ab36404ea853403cc9b7137e8941f09e77be0966153f0d960fe2cfc3238b6a7467c9648ba00e1610eb4c29086187c56 WHIRLPOOL 58dd2cb23ad0c34eb8ee97bfa5b817ef1d0e102b7b49dd3451ddf5406318f28ea21ea8ce76a6461980ebf69780d02e266b2d928502151b703177985505f2ef2c

EBUILD emacs-vcs-25.0.9999-r99.ebuild 11389 SHA256 4b06d5b9f9730cc81b23a2c1cde41fd07f4a5df0fdcc7f85b9eb268bf9bab1e7 SHA512 2ddf5e70978490a17f301de67fd9224e03a200cf3c76b24d6a62f2631261459dbb17bf6fe78b1217d4942fd6d335145d369fbc6e829b67f934b8c917bda3ef9d WHIRLPOOL f74590055432141746c7dc80a63fe8f61f09370bc3a766c2226c9bb97fc78d0446d81f347aeda6afea0812789a093c4188c93c114272783db4a39b2b02f31f2c

MISC metadata.xml 2489 SHA256 21b3602d37aa25bca31b05ea810b37ee2192f4e53b8f8daeb814d9dca59d03d7 SHA512 4f3d663cd61253ae3390c55c5974dd3cc22dbf1306a823c3cb71794d09eaf28d7727c7e24f66f02dbd8d3845894f3a8cafa5ddaf330c1bbb7f99d8130ece077c WHIRLPOOL bcefdded503fa9cebea943952d3f56847002cb5ddc10f5adbd774301b648d1b12a09da7e493694f9cbbb19e8b53b66132cbd2e0141ded41b226415cfdbbcf8f6

# Copyright 1999-2014 Gentoo Foundation

# Distributed under the terms of the GNU General Public License v2

# $Header: /var/cvsroot/gentoo-x86/app-editors/emacs-vcs/emacs-vcs-25.0.9999-r1.ebuild,v 1.3 2014/12/29 11:28:11 ulm Exp $

EAPI=5

inherit autotools elisp-common eutils flag-o-matic multilib readme.gentoo

if [[ ${PV##*.} = 9999 ]]; then

	inherit git-r3

	EGIT_REPO_URI="git://git.sv.gnu.org/emacs.git"

	EGIT_BRANCH="master"

	EGIT_CHECKOUT_DIR="${WORKDIR}/emacs"

	S="${EGIT_CHECKOUT_DIR}"

else

	SRC_URI="http://dev.gentoo.org/~ulm/distfiles/emacs-${PV}.tar.xz

		mirror://gnu-alpha/emacs/pretest/emacs-${PV}.tar.xz"

	KEYWORDS="~amd64 ~arm ~ppc ~x86"

	# FULL_VERSION keeps the full version number, which is needed in

	# order to determine some path information correctly for copy/move

	# operations later on

	FULL_VERSION="${PV%%_*}"

	#S="${WORKDIR}/emacs-${FULL_VERSION}"

	S="${WORKDIR}/emacs"

fi

DESCRIPTION="The extensible, customizable, self-documenting real-time display editor"

HOMEPAGE="http://www.gnu.org/software/emacs/"

LICENSE="GPL-3+ FDL-1.3+ BSD HPND MIT W3C unicode PSF-2"

SLOT="25"

IUSE="acl alsa aqua athena dbus games gconf gfile gif gnutls gpm gsettings gtk +gtk3 gzip-el hesiod imagemagick +inotify jpeg kerberos libxml2 livecd m17n-lib motif pax_kernel png selinux sound source svg tiff toolkit-scroll-bars wide-int X Xaw3d xft +xpm zlib"

REQUIRED_USE="?? ( aqua X )"

RDEPEND="sys-libs/ncurses

	>=app-admin/eselect-emacs-1.16

	>=app-emacs/emacs-common-gentoo-1.4-r1[games?,X?]

	net-libs/liblockfile

	acl? ( virtual/acl )

	alsa? ( media-libs/alsa-lib )

	dbus? ( sys-apps/dbus )

	gfile? ( >=dev-libs/glib-2.28.6 )

	gnutls? ( net-libs/gnutls )

	gpm? ( sys-libs/gpm )

	hesiod? ( net-dns/hesiod )

	kerberos? ( virtual/krb5 )

	libxml2? ( >=dev-libs/libxml2-2.2.0 )

	selinux? ( sys-libs/libselinux )

	zlib? ( sys-libs/zlib )

	X? (

		x11-libs/libXmu

		x11-libs/libXt

		x11-misc/xbitmaps

		gconf? ( >=gnome-base/gconf-2.26.2 )

		gsettings? ( >=dev-libs/glib-2.28.6 )

		gif? ( media-libs/giflib )

		jpeg? ( virtual/jpeg:0= )

		png? ( >=media-libs/libpng-1.4:0= )

		svg? ( >=gnome-base/librsvg-2.0 )

		tiff? ( media-libs/tiff )

		xpm? ( x11-libs/libXpm )

		imagemagick? ( >=media-gfx/imagemagick-6.6.2 )

		xft? (

			media-libs/fontconfig

			media-libs/freetype

			x11-libs/libXft

			m17n-lib? (

				>=dev-libs/libotf-0.9.4

				>=dev-libs/m17n-lib-1.5.1

			)

		)

		gtk? (

			gtk3? ( x11-libs/gtk+:3 )

			!gtk3? ( x11-libs/gtk+:2 )

		)

		!gtk? (

			motif? ( >=x11-libs/motif-2.3:0 )

			!motif? (

				Xaw3d? ( x11-libs/libXaw3d )

				!Xaw3d? ( athena? ( x11-libs/libXaw ) )

			)

		)

	)"

DEPEND="${RDEPEND}

	virtual/pkgconfig

	gzip-el? ( app-arch/gzip )

	pax_kernel? (

		sys-apps/attr

		sys-apps/paxctl

	)"

if [[ ${PV##*.} = 9999 ]]; then

	DEPEND="${DEPEND}

	sys-apps/texinfo"

fi

EMACS_SUFFIX="${PN/emacs/emacs-${SLOT}}"

SITEFILE="20${PN}-${SLOT}-gentoo.el"

src_prepare() {

	epatch "${FILESDIR}"/${PN}-musl.patch

	if [[ ${PV##*.} = 9999 ]]; then

		FULL_VERSION=$(sed -n 's/^AC_INIT([^,]*,[ \t]*\([^ \t,)]*\).*/\1/p' \

			configure.ac)

		[[ ${FULL_VERSION} ]] || die "Cannot determine current Emacs version"

		einfo "Emacs branch: ${EGIT_BRANCH}"

		einfo "Commit: ${EGIT_VERSION}"

		einfo "Emacs version number: ${FULL_VERSION}"

		[[ ${FULL_VERSION} =~ ^${PV%.*}(\..*)?$ ]] \

			|| die "Upstream version number changed to ${FULL_VERSION}"

	fi

	epatch_user

	# Fix filename reference in redirected man page

	sed -i -e "/^\\.so/s/etags/&-${EMACS_SUFFIX}/" doc/man/ctags.1 \

		|| die "unable to sed ctags.1"

	AT_M4DIR=m4 eautoreconf

}

src_configure() {

	strip-flags

	filter-flags -pie					#526948

	if use sh; then

		replace-flags "-O[1-9]" -O0		#262359

	elif use ia64; then

		replace-flags "-O[2-9]" -O1		#325373

	else

		replace-flags "-O[3-9]" -O2

	fi

	local myconf

	if use alsa; then

		use sound || ewarn \

			"USE flag \"alsa\" overrides \"-sound\"; enabling sound support."

		myconf+=" --with-sound=alsa"

	else

		myconf+=" --with-sound=$(usex sound oss)"

	fi

	if use X; then

		myconf+=" --with-x --without-ns"

		myconf+=" $(use_with gconf)"

		myconf+=" $(use_with gsettings)"

		myconf+=" $(use_with toolkit-scroll-bars)"

		myconf+=" $(use_with gif)"

		myconf+=" $(use_with jpeg)"

		myconf+=" $(use_with png)"

		myconf+=" $(use_with svg rsvg)"

		myconf+=" $(use_with tiff)"

		myconf+=" $(use_with xpm)"

		myconf+=" $(use_with imagemagick)"

		if use xft; then

			myconf+=" --with-xft"

			myconf+=" $(use_with m17n-lib libotf)"

			myconf+=" $(use_with m17n-lib m17n-flt)"

		else

			myconf+=" --without-xft"

			myconf+=" --without-libotf --without-m17n-flt"

			use m17n-lib && ewarn \

				"USE flag \"m17n-lib\" has no effect if \"xft\" is not set."

		fi

		local f

		if use gtk; then

			einfo "Configuring to build with GIMP Toolkit (GTK+)"

			myconf+=" --with-x-toolkit=$(usex gtk3 gtk3 gtk2)"

			for f in motif Xaw3d athena; do

				use ${f} && ewarn \

					"USE flag \"${f}\" has no effect if \"gtk\" is set."

			done

		elif use motif; then

			einfo "Configuring to build with Motif toolkit"

			myconf+=" --with-x-toolkit=motif"

			for f in Xaw3d athena; do

				use ${f} && ewarn \

					"USE flag \"${f}\" has no effect if \"motif\" is set."

			done

		elif use athena || use Xaw3d; then

			einfo "Configuring to build with Athena/Lucid toolkit"

			myconf+=" --with-x-toolkit=lucid $(use_with Xaw3d xaw3d)"

		else

			einfo "Configuring to build with no toolkit"

			myconf+=" --with-x-toolkit=no"

		fi

	elif use aqua; then

		einfo "Configuring to build with Nextstep (Cocoa) support"

		myconf+=" --with-ns --disable-ns-self-contained"

		myconf+=" --without-x"

	else

		myconf+=" --without-x --without-ns"

	fi

	# Save version information in the Emacs binary. It will be available

	# in variable "system-configuration-options".

	myconf+=" GENTOO_PACKAGE=${CATEGORY}/${PF}"

	if [[ ${PV##*.} = 9999 ]]; then

		myconf+=" EGIT_BRANCH=${EGIT_BRANCH} EGIT_VERSION=${EGIT_VERSION}"

	fi

	econf \

		--program-suffix="-${EMACS_SUFFIX}" \

		--infodir="${EPREFIX}"/usr/share/info/${EMACS_SUFFIX} \

		--localstatedir="${EPREFIX}"/var \

		--enable-locallisppath="${EPREFIX}/etc/emacs:${EPREFIX}${SITELISP}" \

		--with-gameuser="${GAMES_USER_DED:-games}" \

		--without-compress-install \

		--with-file-notification=$(usev gfile || usev inotify || echo no) \

		$(use_enable acl) \

		$(use_with dbus) \

		$(use_with gnutls) \

		$(use_with gpm) \

		$(use_with hesiod) \

		$(use_with kerberos) $(use_with kerberos kerberos5) \

		$(use_with libxml2 xml2) \

		$(use_with selinux) \

		$(use_with wide-int) \

		$(use_with zlib) \

		${myconf}

}

src_compile() {

	export SANDBOX_ON=0			# for the unbelievers, see Bug #131505

	emake

}

src_install () {

	emake DESTDIR="${D}" NO_BIN_LINK=t install

	mv "${ED}"/usr/bin/{emacs-${FULL_VERSION}-,}${EMACS_SUFFIX} \

		|| die "moving emacs executable failed"

	mv "${ED}"/usr/share/man/man1/{emacs-,}${EMACS_SUFFIX}.1 \

		|| die "moving emacs man page failed"

	# move info dir to avoid collisions with the dir file generated by portage

	mv "${ED}"/usr/share/info/${EMACS_SUFFIX}/dir{,.orig} \

		|| die "moving info dir failed"

	touch "${ED}"/usr/share/info/${EMACS_SUFFIX}/.keepinfodir

	docompress -x /usr/share/info/${EMACS_SUFFIX}/dir.orig

	# avoid collision between slots, see bug #169033 e.g.

	rm "${ED}"/usr/share/emacs/site-lisp/subdirs.el

	rm -rf "${ED}"/usr/share/{appdata,applications,icons}

	rm -rf "${ED}"/var

	# remove unused <version>/site-lisp dir

	rm -rf "${ED}"/usr/share/emacs/${FULL_VERSION}/site-lisp

	# remove COPYING file (except for etc/COPYING used by describe-copying)

	rm "${ED}"/usr/share/emacs/${FULL_VERSION}/lisp/COPYING

	if use gzip-el; then

		# compress .el files when a corresponding .elc exists

		find "${ED}"/usr/share/emacs/${FULL_VERSION}/lisp -type f \

			-name "*.elc" -print | sed 's/\.elc$/.el/' | xargs gzip -9n

		assert "gzip .el failed"

	fi

	local cdir

	if use source; then

		cdir="/usr/share/emacs/${FULL_VERSION}/src"

		insinto "${cdir}"

		# This is not meant to install all the source -- just the

		# C source you might find via find-function

		doins src/*.{c,h,m}

	elif has installsources ${FEATURES}; then

		cdir="/usr/src/debug/${CATEGORY}/${PF}/${S#"${WORKDIR}/"}/src"

	fi

	sed -e "${cdir:+#}/^Y/d" -e "s/^[XY]//" >"${T}/${SITEFILE}" <<-EOF

	X

	;;; ${PN}-${SLOT} site-lisp configuration

	X

	(when (string-match "\\\\\`${FULL_VERSION//./\\\\.}\\\\>" emacs-version)

	Y  (setq find-function-C-source-directory

	Y	"${EPREFIX}${cdir}")

	X  (let ((path (getenv "INFOPATH"))

	X	(dir "${EPREFIX}/usr/share/info/${EMACS_SUFFIX}")

	X	(re "\\\\\`${EPREFIX}/usr/share/info\\\\>"))

	X    (and path

	X	 ;; move Emacs Info dir before anything else in /usr/share/info

	X	 (let* ((p (cons nil (split-string path ":" t))) (q p))

	X	   (while (and (cdr q) (not (string-match re (cadr q))))

	X	     (setq q (cdr q)))

	X	   (setcdr q (cons dir (delete dir (cdr q))))

	X	   (setq Info-directory-list (prune-directory-list (cdr p)))))))

	EOF

	elisp-site-file-install "${T}/${SITEFILE}" || die

	dodoc README BUGS CONTRIBUTE

	if use aqua; then

		dodir /Applications/Gentoo

		rm -rf "${ED}"/Applications/Gentoo/Emacs${EMACS_SUFFIX#emacs}.app

		mv nextstep/Emacs.app \

			"${ED}"/Applications/Gentoo/Emacs${EMACS_SUFFIX#emacs}.app || die

	fi

	DOC_CONTENTS="You can set the version to be started by /usr/bin/emacs

		through the Emacs eselect module, which also redirects man and info

		pages. Therefore, several Emacs versions can be installed at the

		same time. \"man emacs.eselect\" for details.

		\\n\\nIf you upgrade from Emacs version 24.2 or earlier, then it is

		strongly recommended that you use app-admin/emacs-updater to rebuild

		all byte-compiled elisp files of the installed Emacs packages."

	use X && DOC_CONTENTS+="\\n\\nYou need to install some fonts for Emacs.

		Installing media-fonts/font-adobe-{75,100}dpi on the X server's

		machine would satisfy basic Emacs requirements under X11.

		See also https://wiki.gentoo.org/wiki/Xft_support_for_GNU_Emacs

		for how to enable anti-aliased fonts."

	use aqua && DOC_CONTENTS+="\\n\\nEmacs${EMACS_SUFFIX#emacs}.app is in

		\"${EPREFIX}/Applications/Gentoo\". You may want to copy or symlink

		it into /Applications by yourself."

	readme.gentoo_create_doc

}

pkg_preinst() {

	# move Info dir file to correct name

	local infodir=/usr/share/info/${EMACS_SUFFIX} f

	if [[ -f ${ED}${infodir}/dir.orig ]]; then

		mv "${ED}"${infodir}/dir{.orig,} || die "moving info dir failed"

	elif [[ -d "${ED}"${infodir} ]]; then

		# this should not happen in EAPI 4

		ewarn "Regenerating Info directory index in ${infodir} ..."

		rm -f "${ED}"${infodir}/dir{,.*}

		for f in "${ED}"${infodir}/*; do

			if [[ ${f##*/} != *-[0-9]* && -e ${f} ]]; then

				install-info --info-dir="${ED}"${infodir} "${f}" \

					|| die "install-info failed"

			fi

		done

	fi

}

pkg_postinst() {

	elisp-site-regen

	local pvr

	for pvr in ${REPLACING_VERSIONS}; do

		[[ ${pvr%%[-_]*} = 24.[12] ]] && FORCE_PRINT_ELOG=1

	done

	readme.gentoo_print_elog

	if use livecd; then

		# force an update of the emacs symlink for the livecd/dvd,

		# because some microemacs packages set it with USE=livecd

		eselect emacs update

	elif [[ $(readlink "${EROOT}"/usr/bin/emacs) = ${EMACS_SUFFIX} ]]; then

		# refresh symlinks in case any installed files have changed

		eselect emacs set ${EMACS_SUFFIX}

	else

		eselect emacs update ifunset

	fi

}

pkg_postrm() {

	elisp-site-regen

	eselect emacs update ifunset

}

http://www.openwall.com/lists/musl/2015/02/03/1

--- emacs-4188e3cc2bc69e75d4387b369e72e89fecc46a86/configure.ac

+++ emacs/configure.ac

@@ -2092,7 +2092,7 @@

 system_malloc=$emacs_cv_sanitize_address

-hybrid_malloc=

+hybrid_malloc=yes

 case "$opsys" in

   ## darwin ld insists on the use of malloc routines in the System framework.

--- emacs-4188e3cc2bc69e75d4387b369e72e89fecc46a86/src/Makefile.in

+++ emacs/src/Makefile.in

@@ -373,6 +373,7 @@

 	region-cache.o sound.o atimer.o \

 	doprnt.o intervals.o textprop.o composite.o xml.o $(NOTIFY_OBJ) \

 	profiler.o decompress.o \

+	sheap.o \

 	$(MSDOS_OBJ) $(MSDOS_X_OBJ) $(NS_OBJ) $(CYGWIN_OBJ) $(FONT_OBJ) \

 	$(W32_OBJ) $(WINDOW_SYSTEM_OBJ) $(XGSELOBJ)

 obj = $(base_obj) $(NS_OBJC_OBJ)

--- emacs-4188e3cc2bc69e75d4387b369e72e89fecc46a86/src/gmalloc.c

+++ emacs/src/gmalloc.c

@@ -72,7 +72,7 @@

 #define free gfree

 #endif  /* HYBRID_MALLOC */

-#ifdef CYGWIN

+//#ifdef CYGWIN

 extern void *bss_sbrk (ptrdiff_t size);

 extern int bss_sbrk_did_unexec;

 extern char bss_sbrk_buffer[];

@@ -80,7 +80,7 @@

 #define DUMPED bss_sbrk_did_unexec

 #define ALLOCATED_BEFORE_DUMPING(P) \

   ((P) < bss_sbrk_buffer_end && (P) >= (void *) bss_sbrk_buffer)

-#endif

+//#endif

 #ifdef	__cplusplus

 extern "C"

@@ -1525,16 +1525,19 @@

 __default_morecore (ptrdiff_t increment)

 {

   void *result;

-#if defined (CYGWIN)

+//#if defined (CYGWIN)

   if (!DUMPED)

     {

       return bss_sbrk (increment);

     }

-#endif

+//#endif

+#if 0

   result = (void *) __sbrk (increment);

   if (result == (void *) -1)

     return NULL;

   return result;

+#endif

+  return NULL;

 }

 /* Copyright (C) 1991, 92, 93, 94, 95, 96 Free Software Foundation, Inc.

--- emacs-4188e3cc2bc69e75d4387b369e72e89fecc46a86/src/print.c

+++ emacs/src/print.c

@@ -755,7 +755,7 @@

   print_output_debug_flag = x;

 }

-#if defined (GNU_LINUX)

+#if defined (GNU_LINUX) && defined (__GLIBC__)

 /* This functionality is not vitally important in general, so we rely on

    non-portable ability to use stderr as lvalue.  */

--- emacs-4188e3cc2bc69e75d4387b369e72e89fecc46a86/src/unexelf.c

+++ emacs/src/unexelf.c

@@ -632,6 +632,9 @@

   off_t new_file_size;

   void *new_break;

+  extern int bss_sbrk_did_unexec;

+  bss_sbrk_did_unexec = 1;

+

   /* Pointers to the base of the image of the two files.  */

   caddr_t old_base, new_base;