lxdm ebuild

lxdm-0.5.0-r3.ebuild (text/plain), 1.66 KB, created by Joakim Tjernlund on 2015-01-17 17:39:27 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2


EAPI="4"

WANT_AUTOMAKE="1.13"
inherit eutils pam autotools systemd

DESCRIPTION="LXDE Display Manager"
HOMEPAGE="http://lxde.org"
SRC_URI="mirror://sourceforge/lxdm/${P}.tar.xz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="amd64 ~arm ~ppc x86"

IUSE="consolekit debug gtk3 nls pam"

RDEPEND="consolekit? ( sys-auth/consolekit )
	x11-libs/libxcb
	gtk3? ( x11-libs/gtk+:3 )
	!gtk3? ( x11-libs/gtk+:2 )
	nls? ( sys-devel/gettext )
	pam? ( virtual/pam )"
DEPEND="${RDEPEND}
	>=dev-util/intltool-0.40
	virtual/pkgconfig"

src_prepare() {
	# Upstream bug, tarball contains pre-made lxdm.conf
	rm "${S}"/data/lxdm.conf || die

	# this replaces the bootstrap/autogen script in most packages
	eautoreconf

	# process LINGUAS
	if use nls; then
		einfo "Running intltoolize ..."
		intltoolize --force --copy --automake || die
		strip-linguas -i "${S}/po" || die
	fi
}
src_configure() {
	econf	--enable-password \
		--with-x \
		--with-xconn=xcb \
		$(use_enable consolekit) \
		$(use_enable gtk3) \
		$(use_enable nls) \
		$(use_enable debug) \
		$(use_with pam)
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS README TODO || die
	systemd_dounit "${FILESDIR}"/${PN}.service

	# Remove existing pam file. We will build a new one. Bug #533338
	rm -rf "${ED}"/etc/pam.d/${PN}
	pamd_mimic system-local-login ${PN} auth account password session #37222

	#Use Gentoo specific Xsession startup file
	insinto /etc/${PN}
	doins "${FILESDIR}"/Xsession
	fperms +x /etc/${PN}/Xsession
}

pkg_postinst() {
	echo
	elog "Take into consideration that LXDM is in the early stages of development!"
	echo
}