# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-fonts/source-pro/source-pro-20130316.ebuild,v 1.2 2013/10/21 12:18:39 grobian Exp $

EAPI=5
inherit font

SANS_P=source-sans-pro-2.010R-ro-1.065R-it
SERIF_P=source-serif-pro-1.017R
CODE_P=source-code-pro-1.017R
HAN_SANS=source-han-sans-1.001R

DESCRIPTION="Adobe Source Pro, an open source multi-lingual font family"
HOMEPAGE="http://blog.typekit.com/2012/08/02/source-sans-pro/
	http://blog.typekit.com/2012/09/24/source-code-pro/"
SRC_URI="https://github.com/adobe-fonts/source-sans-pro/archive/2.010R-ro/1.065R-it.tar.gz -> ${SANS_P}.tar.gz
	https://github.com/adobe-fonts/source-serif-pro/archive/1.017R.tar.gz -> ${SERIF_P}.tar.gz
	https://github.com/adobe-fonts/source-code-pro/archive/1.017R.tar.gz -> ${CODE_P}.tar.gz
	cjk? ( https://github.com/adobe-fonts/source-han-sans/archive/1.001R.tar.gz -> ${HAN_SANS}.tar.gz )"

LICENSE="OFL-1.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x64-macos"
IUSE="-cjk"

# This ebuild does not install any binaries
RESTRICT="binchecks strip mirror"

RDEPEND="media-libs/fontconfig"
DEPEND=""

S="${WORKDIR}"
FONT_SUFFIX="otf"
FONT_S=${S}
FONT_CONF=( "${FILESDIR}"/63-${PN}.conf )

src_prepare() {
	mv ${SANS_P}/OTF/*.otf .
	mv ${SERIF_P}/OTF/*.otf .
	mv ${CODE_P}/OTF/*.otf .
	if use cjk ; then
	  mv ${HAN_SANS}/SubsetOTF/*/*.otf .
	fi
	chmod a-x *.otf
}

src_install() {
	font_src_install
	dodoc ${SANS_P}/{README.md,ReadMe.html,source-sans-pro.css,SourceSansProReadMe.html}
	dodoc ${SERIF_P}/{source-serif-pro.css,SourceSerifProReadMe.html}
	dodoc ${CODE_P}/SourceCodeProReadMe.html
	if use cjk ; then
	  dodoc ${HAN_SANS}/{SourceHanSansDesignGuide.pdf,SourceHanSansReadMe.pdf}
	fi
}