# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/kdevelop-python/kdevelop-python-1.7.0.ebuild,v 1.1 2014/12/26 13:04:30 kensington Exp $

EAPI=5

KDEBASE="kdevelop"
KMNAME="kdev-python"
KDE_LINGUAS="ca de en_GB es et fi fr nl pl pt pt_BR sk sl sv uk"
PYTHON_COMPAT=( python{2_7,3_4} )
PYTHON_SINGLE_TARGET="python2_7"
EGIT_BRANCH="1.7"
MY_P="${KMNAME}-${PV}"
inherit kde4-base python-single-r1

if [[ ${KDE_BUILD_TYPE} = release ]]; then

	SRC_URI=""
	for p2version in $( python_gen_useflags 'python2*'); do
		SRC_URI="$SRC_URI
		${p2version}? ( mirror://kde/stable/kdevelop/${KDEVELOP_VERSION}/src/${MY_P}.tar.xz )"
		if use ${p2version}; then
			S=${WORKDIR}/${MY_P}
		fi
	done
	
	for p3version in $( python_gen_useflags 'python3*'); do
		SRC_URI="$SRC_URI
		${p3version}? ( mirror://kde/stable/kdevelop/${KDEVELOP_VERSION}/src/${MY_P}-py3.tar.xz )"
		if use ${p3version}; then
			S=${WORKDIR}/${MY_P}-py3
		fi
	done

	KEYWORDS="~amd64 ~x86"

fi

DESCRIPTION="Python plugin for KDevelop 4"
IUSE="debug"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

COMMON_DEPEND=">=dev-util/kdevplatform-${PV}:4"
DEPEND="${COMMON_DEPEND}
	${PYTHON_DEPS}
"
RDEPEND="
	${COMMON_DEPEND}
	dev-util/kdevelop:4
"

RESTRICT="test"

pkg_setup() {
	python-single-r1_pkg_setup
	kde4-base_pkg_setup
}

src_compile() {
	pushd "${WORKDIR}"/${P}_build > /dev/null
	emake parser
	popd > /dev/null

	kde4-base_src_compile
}