stepmania-3.9_alpha20.ebuild

stepmania-3.9_alpha20.ebuild (text/plain), 1.79 KB, created by Sean Burke on 2004-09-09 14:02:30 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

IUSE="debug gtk jpeg mad mpeg oggvorbis"

MY_PV="${PV/_/-}"
S="${WORKDIR}/StepMania-${MY_PV}-src"
SMDATA="${WORKDIR}/StepMania-${MY_PV}"
DESCRIPTION="An advanced DDR simulator"
HOMEPAGE="http://www.stepmania.com/stepmania/"
SRC_URI="mirror://sourceforge/stepmania/StepMania-${MY_PV}-src.tar.gz
	mirror://sourceforge/stepmania/StepMania-${MY_PV}-linux.tar.gz"

SLOT="0"
LICENSE="MIT"
KEYWORDS="~x86"

DEPEND="gtk? ( >=x11-libs/gtk+-2.0 )
	mad? ( media-libs/libmad )
	=dev-lang/lua-5.0
	>=media-libs/libsdl-1.2.6
	jpeg? ( media-libs/jpeg )
	media-libs/libpng
	sys-libs/zlib
	mpeg? ( <=media-video/ffmpeg-0.4.8 )
	oggvorbis? ( media-libs/libvorbis )
	virtual/opengl"

pkg_setup() {
	games_pkg_setup
}

src_unpack() {
	unpack ${A}
	epatch ${FILESDIR}/stepmania-${PV}-gentoo.patch
	cd ${S}
}

src_compile() {
	local myconf
	use debug && myconf="${myconf} --with-debug"
	use jpeg || myconf="${myconf} --without-jpeg"
	use oggvorbis || myconf="${myconf} --without-vorbis"	
	use mad || myconf="${myconf} --without-mp3"
	use gtk || myconf="${myconf} --disable-gtk2"

	econf ${myconf} || die "Configure failed"

	emake || die "Make failed"
}

src_install() {
	local dir=${GAMES_PREFIX_OPT}/${PN}

	dodir ${dir}
	exeinto ${dir}
	doexe src/stepmania || die "Install failed"
	if use gtk; then
		doexe src/GtkModule.so || die "Install failed"
	fi

	cd ${SMDATA}

	insinto ${dir}
	doins COPYING.txt NEWS README-FIRST.html

	cp -r Announcers BGAnimations CDTitles Characters Courses Data \
		Docs NoteSkins RandomMovies Songs Themes Visualizations ${D}/${dir} || die "Install failed"

	games_make_wrapper stepmania ${dir}/stepmania ${dir}

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
}