dev-lua/specl-13.ebuild

specl-13.ebuild (text/plain), 1.19 KB, created by Dennis Schridde on 2014-12-18 15:19:20 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

[[ "${PV}" = *9999* ]] && live=git-r3
inherit ${live}

MY_PV="release-v${PV}"

DESCRIPTION="Behaviour Driven Development for Lua"
HOMEPAGE="http://gvvaughan.github.io/specl"
if [[ "${PV}" = *9999* ]] ; then
	EGIT_REPO_URI="https://github.com/gvvaughan/${PN}.git"
	KEYWORDS="-*"
else
	SRC_URI="https://github.com/gvvaughan/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64"
fi

LICENSE="GPL-3"
SLOT="0"

IUSE="luajit test"

RDEPEND="!luajit? ( || ( dev-lang/lua:5.1 >=dev-lang/lua-5.1:0 ) )
	luajit? ( dev-lang/luajit:2 )
	>=dev-lua/LuaMacro-2
	>=dev-lua/lyaml-5
	=dev-lua/lua-stdlib-40"
DEPEND="${RDEPEND}
	test? ( >=dev-lua/specl-5 )
	sys-apps/help2man
	sys-apps/grep
	sys-apps/sed"

DOCS=( "README" "NEWS" )

S="${WORKDIR}/${PN}-${MY_PV}"

src_prepare() {
	ln -s "${EPREFIX}"/usr/share/slingshot . || die

	# WARNING: Order matters! Slingshot options are processed first and are ignored otherwise!
	./bootstrap --skip-rock-checks --skip-git --skip-po || die
}

src_configure() {
	local lua=lua
	use luajit && lua=luajit

	econf \
		LUA="${lua}"
}

src_test() {
	emake check
}