# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: 

inherit eutils

DESCRIPTION="IrDA Utilities, tools for IrDA communication"
SRC_URI="mirror://sourceforge/irda/${P}.tar.gz"
RESTRICT="nomirror"
HOMEPAGE="http://irda.sf.net"
KEYWORDS="~x86 ~ppc"
SLOT="0"
LICENSE="GPL-2"

DEPEND="virtual/glibc >=dev-libs/glib-2"

src_unpack() {
	unpack ${A}

	cd ${S}
	epatch ${FILESDIR}/${PN}-gtk+2.patch
	epatch ${FILESDIR}/${PN}-includes.patch
	epatch ${FILESDIR}/${PN}-makefiles.patch
	epatch ${FILESDIR}/${PN}-irkbd-error.patch
	if ! use x86; then
		epatch ${FILESDIR}/${PN}-not-x86.patch
	fi

	export WANT_AUTOCONF=2.5
}

src_compile() {
	if use x86; then
		cd ${S}/findchip
		emake GCFLAGS="${CFLAGS}" || die "Making findchip failed"
	fi

	cd ${S}/irdadump
	libtoolize
	aclocal
	autoconf
	autoheader
	econf
	emake || die "Making irdadump failed"

	for i in irattach irdaping irsockets psion tekram
	do
		cd ${S}/${i}
		emake GCFLAGS="${CFLAGS}" || die "Making ${i} failed"
	done
}

src_install () {
	addpredict /usr/bin/irdadump

	dodir /usr/bin
	dodir /usr/sbin
	dodir /usr/X11R6/bin

	make install PREFIX="${D}" ROOT="${D}" || die "Couldn't install from ${S}"

	# irda-utils's install-etc installs files in /etc/sysconfig if
	# that directory exists on the system, so clean up just in case.
	# This is for bug 1797 (17 Jan 2004 agriffis)
	rm -rf ${D}/etc/sysconfig 2>/dev/null

	into /usr
	dobin irsockets/irdaspray
	dobin irsockets/ias_query
	dobin irsockets/irprintf
	dobin irsockets/irprintfx
	dobin irsockets/irscanf
	dobin irsockets/recv_ultra
	dobin irsockets/send_ultra
	dobin irdadump/shell/irdadump
	dobin psion/irpsion5

	if use x86; then
		dosbin findchip/findchip
	fi

	dosbin irattach/irattach
	dosbin irattach/dongle_attach
	dosbin irdaping/irdaping
	dosbin tekram/irkbd

	# install README's into /usr/share/doc
	for i in *
	do
		if [ -d $i -a $i != "man" ]; then
			if [ -f $i/README ]; then
				cp $i/README README.$i
				dodoc README.$i
				rm README.$i
			fi
		fi
	done

	insinto /etc/conf.d ; newins ${FILESDIR}/irda.conf irda
	insinto /etc/init.d ; insopts -m0755 ; newins ${FILESDIR}/irda.rc irda
}