fwknop-2.6.4.ebuild

fwknop-2.6.4-r9999.ebuild (text/plain), 3.01 KB, created by Coacher on 2014-11-19 15:39:27 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

# does work with python 2.7, does not work with python 3.3 on my machine
# more feedback is welcome
PYTHON_COMPAT=( python2_7 )
DISTUTILS_OPTIONAL=1
AUTOTOOLS_AUTORECONF=1
AUTOTOOLS_IN_SOURCE_BUILD=1
inherit autotools-utils distutils-r1 systemd

DESCRIPTION="Single Packet Authorization and Port Knocking application"
HOMEPAGE="http://www.cipherdyne.org/fwknop/"
SRC_URI="https://github.com/mrash/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="client extras gdbm gpg python server udp-server"

RDEPEND="python? ( ${PYTHON_DEPS} )
	client? ( net-misc/wget[ssl] )
	gpg? (
		dev-libs/libassuan
		dev-libs/libgpg-error
	)"

DEPEND="${RDEPEND}
	gdbm? ( sys-libs/gdbm )
	gpg? ( app-crypt/gpgme )
	server? (
		!udp-server? ( net-libs/libpcap )
		net-firewall/iptables
	)"

REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
	udp-server? ( server )"

DOCS=( ChangeLog README.md )

# Remove extra run/ subdir from localstatedir paths
#
# fwknopd's default location for digest-cache and pidfile is
# localstatedir/run/fwknop (see server/fwknopd_common.h).
# Such files (cache, pidfile) should be placed in /run/fwknop instead.
# fwknopd's default apparmor policy also assumes that these files are in
# /run/fwknop, i.e. localstatedir is /var and /var/run is a symlink to /run.
# Relying on /var/run -> /run symlink is not the best practice.
# This is why simply binding localstatedir to /var is not enough.
# Instead we strip hardcoded run/ subdir from localstatedir paths
# ans set localstatedir to /run below.
PATCHES=( "${FILESDIR}/${P}-remove-extra-run-from-paths.patch" )

PATCHES+=(
	"${FILESDIR}/${P}-disable-IP-resolution-in-AFL_FUZZING-mode.patch"
	"${FILESDIR}/${P}-ensure-a-overrides-IP-resolution.patch"
)

src_prepare() {
	# Install example configs with .example suffix
	if use server; then
		sed -i 's/conf;/conf.example;/g' "${S}"/Makefile.am || die
	fi

	autotools-utils_src_prepare

	if use python; then
		# Unset PATCHES since distutils-r1.eclass interferes
		local PATCHES=()
		cd "${S}"/python || die
		distutils-r1_src_prepare
	fi
}

src_configure() {
	local myeconfargs=(
		--localstatedir=/run
		--enable-digest-cache
		$(use_enable client)
		$(use_enable !gdbm file-cache)
		$(use_enable server)
		$(use_enable udp-server)
		$(use_with gpg gpgme)
	)
	autotools-utils_src_configure
}

src_compile() {
	autotools-utils_src_compile

	if use python; then
		cd "${S}"/python || die
		distutils-r1_src_compile
	fi
}

src_install() {
	autotools-utils_src_install
	prune_libtool_files --modules

	if use server; then
		newinitd "${FILESDIR}/fwknopd.init" fwknopd
		newconfd "${FILESDIR}/fwknopd.confd" fwknopd
		systemd_newtmpfilesd "${FILESDIR}/fwknopd.tmpfiles.conf" fwknopd.conf
	fi

	use extras && dodoc "${S}/extras/apparmor/usr.sbin.fwknopd"

	if use python; then
		# Unset DOCS since distutils-r1.eclass interferes
		local DOCS=()
		cd "${S}"/python || die
		distutils-r1_src_install
	fi
}