Slightly updated ebuild for alpha version of stepmania

stepmania-3.9.0.22_alpha.ebuild (text/plain), 1.77 KB, created by Flammie Pirinen (RETIRED) on 2004-09-04 19:11:04 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $
inherit eutils

IUSE="debug gtk jpeg mad mpeg oggvorbis"

MY_PV="3.9-alpha22"
S="${WORKDIR}/StepMania-${MY_PV}-src"
SMDATA="${WORKDIR}/StepMania-${MY_PV}"
DESCRIPTION="An advanced DDR simulator"
HOMEPAGE="http://www.stepmania.com/stepmania/"
SRC_URI="mirror://sourceforge/stepmania/StepMania-${MY_PV}-src.tar.gz
	mirror://sourceforge/stepmania/StepMania-${MY_PV}-linux.tar.gz"

SLOT="0"
LICENSE="MIT"
KEYWORDS="-x86"
# alphas shouldn't be distributed as per bug 38613 in gentoo bugzilla
# --flammie

DEPEND="gtk? ( >=x11-libs/gtk+-2.0 )
	mad? ( media-libs/libmad )
	=dev-lang/lua-5.0
	>=media-libs/libsdl-1.2.6
	jpeg? ( media-libs/jpeg )
	media-libs/libpng
	sys-libs/zlib
	mpeg? ( >=media-video/ffmpeg-0.4.9_pre1 )
	oggvorbis? ( media-libs/libvorbis )
	media-libs/libsndfile
	virtual/opengl"

src_unpack() {
	unpack ${A}
	epatch ${FILESDIR}/stepmania-3.9_alpha22-gentoo.patch
	cd ${S}
}

src_compile() {
	local myconf
	use debug && myconf="${myconf} --with-debug"
	use jpeg || myconf="${myconf} --without-jpeg"
	use oggvorbis || myconf="${myconf} --without-vorbis"	
	use mad || myconf="${myconf} --without-mp3"
	use gtk || myconf="${myconf} --disable-gtk2"

	econf ${myconf} || die "Configure failed"

	emake || die "Make failed"
}

src_install() {
	local SMINSDIR="/opt/${PN}/"

	dodir ${SMINSDIR}
	exeinto ${SMINSDIR}
	doexe src/stepmania || die "Install failed"
	if use gtk; then
		doexe src/GtkModule.so || die "Install failed"
	fi

	cd ${SMDATA}

	insinto ${SMINSDIR}
	doins COPYING.txt NEWS README-FIRST.html

	cp -R Announcers BGAnimations CDTitles Characters Courses Data \
		Docs NoteSkins RandomMovies Songs Themes Visualizations ${D}/${SMINSDIR} || die "Install failed"
}