updated ebuild for gramps-4.0.4

gramps-4.0.4.ebuild (text/plain), 1.23 KB, created by Chris Mayo on 2014-11-16 15:32:28 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5
PYTHON_COMPAT=( python3_3 )
DISTUTILS_NO_PARALLEL_BUILD=yes

inherit distutils-r1

MY_PV=${PV/_/}

DESCRIPTION="Genealogical Research and Analysis Management Programming System"
HOMEPAGE="http://www.gramps-project.org/"
SRC_URI="mirror://sourceforge/gramps/Stable/${PN}-${MY_PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+reports gexiv2 map spell webkit"

DEPEND="${PYTHON_DEPS}
	dev-libs/glib
	dev-util/intltool
	gnome-base/librsvg:2
	x11-libs/cairo"
RDEPEND="${PYTHON_DEPS}
	dev-python/pycairo
	>=dev-python/pygobject-3.2.2-r1:3[${PYTHON_USEDEP}]
	x11-libs/gtk+:3[introspection]
	x11-libs/pango[introspection]
	x11-misc/xdg-utils
	gexiv2? ( >=media-libs/gexiv2-0.5[${PYTHON_USEDEP},introspection] )
	map? ( >=sci-geosciences/osm-gps-map-1.0.2[introspection] )
	reports? ( media-gfx/graphviz )
	spell? ( app-text/gtkspell:3[introspection] )
	webkit? ( net-libs/webkit-gtk:3[introspection] )"

DOCS="RELEASE_NOTES FAQ AUTHORS TODO NEWS README ChangeLog"

S=${WORKDIR}/${PN}-${MY_PV}

src_prepare() {
	epatch "${FILESDIR}/${P}-resourcepath.patch"
	
	sed -i "s:share/doc/gramps:share/doc/${PF}:g" setup.py || die
}