supercollider-cvs-20040903.ebuild

supercollider-cvs-20040903.ebuild (text/plain), 1.61 KB, created by CJ Kucera on 2004-09-03 13:51:20 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils
DESCRIPTION="A real time audio synthesis programming language"
HOMEPAGE="http://www.audiosynth.com/"
SRC_URI="${P}.tgz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="emacs"
#RESTRICT="nostrip"
DEPEND="media-sound/jack-audio-connection-kit
	media-libs/alsa-lib
	media-libs/libsndfile
	sys-devel/automake"
#RDEPEND=""

S=${WORKDIR}/SuperCollider3

src_unpack() {
	unpack ${A}
	sed -ie "s:/etc/sclang.cfg:/etc/supercollider/sclang.cfg:" ${S}/source/lang/LangSource/SC_LanguageClient.cpp
	sed -ie "s:/etc/sclang.cfg:/etc/supercollider/sclang.cfg:" ${S}/linux/examples/sclang.cfg.in

	if use emacs; then
		# Adding emacs stuff per linux/scel/README
		echo "# Emacs includes" >> ${S}/linux/examples/sclang.cfg.in
		echo "+@SC_LIB_DIR@/Linux/SCEL" >> ${S}/linux/examples/sclang.cfg.in
	else
		# Uncommenting a line per linux/examples/sclang.cfg.in
		sed -ie "s:#-@SC_LIB_DIR@/Common/GUI/Document.sc:-@SC_LIB_DIR@/Common/GUI/Document.sc:" ${S}/linux/examples/sclang.cfg.in
	fi
}

src_compile() {
	local myconf
	if use emacs; then
		myconf="${myconf} --enable-scel"
	else
		myconf="${myconf} --disable-scel"
	fi

	./linux/bootstrap
	econf ${myconf} || die
	emake || die "emake failed"
	cd ${S}/linux/examples
	make sclang.cfg

	if use emacs; then
		cd ${S}/linux/scel
		emake || die "emake on skel failed"
	fi
}

src_install() {
	einstall || die "einstall failed"
	insinto /etc/supercollider
	doins ${S}/linux/examples/sclang.cfg

	if use emacs; then
		cd ${S}/linux/scel
		einstall || die "einstall on scel failed"
	fi
}