net-misc/gns3-gui-1.1 ebuild

gns3-gui-1.1.ebuild (text/plain), 1.45 KB, created by Aaron Bauman (RETIRED) on 2014-11-01 06:54:02 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI="5"

PYTHON_COMPAT=( python3_3 )

inherit distutils-r1 eutils

DESCRIPTION="Graphical Network Simulator"
HOMEPAGE="http://www.gns3.net/"
SRC_URI="mirror://sourceforge/GNS3/gns3-gui/archive/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"

DEPEND=">=dev-python/libcloud-0.15.1
	>=dev-python/ws4py-0.3.4
	>=dev-python/requests-2.3.0
	>=dev-python/paramiko-1.13.0
	>=net-misc/gns3-server-1.1
	dev-qt/qtgui:4
	dev-qt/qtsvg:4
	>=dev-python/PyQt4-4.6.1[X,svg,${PYTHON_USEDEP}]"
RDEPEND="${DEPEND}"

python_prepare_all() {
	# avoid file collisions caused by required tests
	sed -e "s:find_packages():find_packages(exclude=['tests','tests.*']):" -i setup.py || die
	distutils-r1_python_prepare_all
}

python_install_all() {
	distutils-r1_python_install_all

	doicon "${WORKDIR}/${P}/resources/images/gns3.ico"
	make_desktop_entry "gns3" "GNS3" "/usr/share/pixmaps/gns3.ico" "Utility"
}

pkg_postinst() {
	ewarn "GNS3 has several dependencies that must be enabled manually for additional functionality."
	ewarn ""
	ewarn "The following is a list of dependencies that can be added:"
	ewarn "putty (terminal support), qemu (additional emulation), telnet, virtualbox (host emulation)"
	ewarn "if you require these dependencies please emerge them before gns3"
	ewarn ""
	ewarn "This will also require manual configuration in gns3's preferences to point to the proper path"
}