the_silver_searcher-0.24.1-r1.ebuild

the_silver_searcher-0.24.1.ebuild (text/plain), 1.01 KB, created by M8R-u38wij on 2014-09-27 11:17:06 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/the_silver_searcher/the_silver_searcher-0.24.1.ebuild,v 1.1 2014/08/15 17:52:17 radhermit Exp $

EAPI=5
inherit base autotools bash-completion-r1

DESCRIPTION="A code-searching tool similar to ack, but faster"
HOMEPAGE="http://github.com/ggreer/the_silver_searcher"
SRC_URI="https://github.com/ggreer/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd"
IUSE="lzma zlib"

RDEPEND="dev-libs/libpcre
	lzma? ( app-arch/xz-utils )
	zlib? ( sys-libs/zlib )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

DOCS="README.md"

PATCHES=(
	"${FILESDIR}/${P}-ebuild-type.patch"
)

src_prepare() {
	base_src_prepare
	sed -i '/^dist_bashcomp/d' Makefile.am || die

	eautoreconf
}

src_configure() {
	econf \
		$(use_enable lzma) \
		$(use_enable zlib)
}

src_install() {
	default
	newbashcomp ag.bashcomp.sh ag
}