# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/qupzilla/qupzilla-1.6.6.ebuild,v 1.1 2014/05/28 09:45:47 pinkbyte Exp $

EAPI=5
PLOCALES="ar_SA bg_BG ca_ES cs_CZ de_DE el_GR es_ES es_MX es_VE eu_ES fa_IR fr_FR gl_ES he_IL hu_HU id_ID it_IT ja_JP ka_GE lg lv_LV nl_NL nqo pl_PL pt_BR pt_PT ro_RO ru_RU sk_SK sr_BA sr_BA@latin sr_RS sr_RS@latin sv_SE uk_UA uz@Latn zh_CN zh_TW"
PLUGINS_HASH='b19f6e0b83baca40e96019ccda329b88459e6a7f'
PLUGINS_VERSION='1.6.3' # if there are no updates, we can use the older archive

inherit l10n multilib qmake-utils qt4-r2 vcs-snapshot

DESCRIPTION="Qt WebKit web browser"
HOMEPAGE="http://www.qupzilla.com/"
SRC_URI="https://github.com/QupZilla/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
	https://github.com/QupZilla/${PN}-plugins/archive/${PLUGINS_HASH}.tar.gz -> ${PN}-plugins-${PLUGINS_VERSION}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="dbus debug gnome-keyring kde nonblockdialogs qt4 qt5"

REQUIRED_USE="^^ ( qt4 qt5 )"

RDEPEND="
	dev-libs/openssl:0
	kde? ( kde-base/kwalletd:4 )
	qt4? (
		>=dev-qt/qtcore-4.7:4
		>=dev-qt/qtgui-4.7:4
		>=dev-qt/qtscript-4.7:4
		>=dev-qt/qtsql-4.7:4
		>=dev-qt/qtwebkit-4.7:4
		dbus? ( >=dev-qt/qtdbus-4.7:4 )
	)
	qt5? (
		dev-qt/qtcore:5
		dev-qt/qtgui:5
		dev-qt/linguist:5
		dev-qt/qtconcurrent:5
		dev-qt/qtprintsupport:5
		dev-qt/qtscript:5
		dev-qt/qtsql:5[sqlite]
		dev-qt/qtwebkit:5
		dbus? ( dev-qt/qtdbus:5 )
	)"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

DOCS=( AUTHORS CHANGELOG FAQ README.md )
PATCHES=( "${FILESDIR}/${P}-plugins-version-check-fix.patch" )

src_prepare() {
        rm_loc() {
                sed -i -e "/${1}.ts/d" translations/translations.pri || die
                rm translations/${1}.ts || die
        }
        # remove outdated copies of localizations:
        rm -r bin/locale || die
        # remove empty locale
        rm translations/empty.ts || die

        l10n_find_plocales_changes "translations" "" ".ts"
        l10n_for_each_disabled_locale_do rm_loc
        qt4-r2_src_prepare
}

src_configure() {
        # see BUILDING document for explanation of options
        export QUPZILLA_PREFIX=${EPREFIX}/usr/
        export USE_LIBPATH=${QUPZILLA_PREFIX}$(get_libdir)
        export DISABLE_DBUS=$(use dbus && echo false || echo true)
        export KDE=$(use kde && echo true || echo false) # in future this will enabl$
        export NONBLOCK_JS_DIALOGS=$(use nonblockdialogs && echo true || echo false)
        has_version '>=dev-qt/qtwebkit-4.8.0:4' && export USE_QTWEBKIT_2_2=true

        # needs qtwebkit with webgl enabled (which we currently don't)
        # export USE_WEBGL=$(use webgl && echo true || echo false)

	if use qt4 ; then
		eqmake4  $(use gnome-keyring && echo "DEFINES+=GNOME_INTEGRATION")
	else
		eqmake5  $(use gnome-keyring && echo "DEFINES+=GNOME_INTEGRATION")
	fi
}

src_install() {
	qt4-r2_src_install
}