# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5
inherit linux-info linux-mod
[[ ${PV} == "9999" ]] && inherit git-2

DESCRIPTION="device that allows access to Linux kernel cryptographic drivers"
HOMEPAGE="http://cryptodev-linux.org/index.html"
if [[ ${PV} == "9999" ]] ; then
	EGIT_REPO_URI="http://github.com/nmav/cryptodev-linux.git"
else
	SRC_URI="http://download.gna.org/cryptodev-linux/${PN}-linux-${PV}.tar.gz"
	KEYWORDS="amd64 arm x86"
fi

LICENSE="GPL-2"
SLOT="0"
IUSE="examples"

DEPEND="virtual/linux-sources"
RDEPEND=""
RESTRICT="test"

MODULE_NAMES="cryptodev(extra:${S})"

pkg_setup() {
	if use kernel_linux ; then
		linux-info_pkg_setup
		linux-mod_pkg_setup
	else
		die "cryptodev ebuild only support linux"
	fi
	BUILD_TARGETS="build"
}

src_compile() {
	linux-mod_src_compile
}

src_install() {
	linux-mod_src_install
	if use examples ; then
		docinto examples
		dodoc example/*
	fi
	insinto /usr/include/crypto
	doins crypto/cryptodev.h
}

pkg_postinst() {
	linux-mod_pkg_postinst
}