# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

inherit games git-r3 multilib scons-utils versionator

MY_PV=$(replace_all_version_separators _ "$(get_version_component_range 2-)")
MY_PN=df
MY_P=${MY_PN}_${MY_PV}

DESCRIPTION="A single-player fantasy game"
HOMEPAGE="http://www.bay12games.com/dwarves"
SRC_URI="http://www.bay12games.com/dwarves/${MY_P}_linux.tar.bz2"
EGIT_REPO_URI="https://github.com/Baughn/Dwarf-Fortress--libgraphics-.git"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64 ~x86 -*"
IUSE="debug"

RDEPEND="virtual/glu
	|| (
		(
			media-libs/freetype[abi_x86_32(-)]
			media-libs/libsdl[abi_x86_32(-),opengl,video,X]
			media-libs/libsndfile[abi_x86_32(-),alsa]
			media-libs/openal[abi_x86_32(-)]
			media-libs/sdl-image[abi_x86_32(-),jpeg,png,tiff]
			media-libs/sdl-ttf[abi_x86_32(-)]
			sys-libs/zlib[abi_x86_32(-)]
			x11-libs/cairo[abi_x86_32(-),xcb,X]
			x11-libs/gtk+:2[abi_x86_32(-)]
			x11-libs/libXcomposite[abi_x86_32(-)]
			x11-libs/libXcursor[abi_x86_32(-)]
			x11-libs/pango[abi_x86_32(-),X]
		)
		amd64? (
			app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
			app-emulation/emul-linux-x86-gtklibs[-abi_x86_32(-)]
			app-emulation/emul-linux-x86-opengl[-abi_x86_32(-)]
			app-emulation/emul-linux-x86-sdl[-abi_x86_32(-)]
			app-emulation/emul-linux-x86-soundlibs[-abi_x86_32(-)]
			app-emulation/emul-linux-x86-xlibs[-abi_x86_32(-)]
		)
	)"

S=${WORKDIR}/${MY_PN}_linux
EGIT_CHECKOUT_DIR=${WORKDIR}/Dwarf-Fortress--libgraphics-
QA_PREBUILT="opt/${PN}/libs/Dwarf_Fortress"

src_unpack() {
	default
	git-r3_src_unpack
}

pkg_setup() {
	games_pkg_setup

	if use amd64; then
		if ! has_multilib_profile; then
			ewarn "You must be on a multilib profile to use dwarf fortress!"
			die "No multilib profile"
		fi
		multilib_toolchain_setup x86
	fi
}

src_prepare() {
	rm libs/libgcc_s.so.1
	rm libs/libstdc++.so.6
	mv ../Dwarf-Fortress--libgraphics-/SConstruct . || die
	mv ../Dwarf-Fortress--libgraphics-/g_src/{SConscript,glew.c,glext} g_src || die
	epatch "${FILESDIR}"/ttf_manager_width.patch
}

src_configure() {
	use debug || sed -i -e "s/^debug = True$/debug = False/" g_src/SConscript || die
}

src_compile() {
	escons
}

src_install() {
	# install data-files and libs
	local gamesdir="${GAMES_PREFIX_OPT}/${PN}"
	insinto "${gamesdir}"
	doins -r raw data libs

	# install our wrapper
	sed -e "s:^gamesdir=.*:gamesdir=${gamesdir}:" < "${FILESDIR}"/${PN}-wrapper > ${PN} || die
	dogamesbin ${PN}

	# install docs
	dodoc README.linux *.txt

	prepgamesdirs

	fperms 750 "${gamesdir}"/libs/Dwarf_Fortress
}

pkg_postinst() {
	einfo "System-wide Dwarf Fortress is installed in ${EPREFIX}/opt/dwarf-fortress."
	einfo 'This is copied to $HOME/.dwarf-fortress when dwarf-fortress is run.'
	einfo "Install tilesets, config files, etc there."
	einfo "Missing files will automatically be re-linked by the wrapper in case"
	einfo "of update etc."
}