pipelight-0.2.7.2.ebuild

pipelight-0.2.7.2.ebuild (text/plain), 4.09 KB, created by Michał Zielański on 2014-07-24 18:51:30 UTC

# Distributed under the terms of the GNU General Public License v2

EAPI=5

inherit nsplugins eutils multilib

DESCRIPTION="A browser plugin which allows one to use windows-only plugins inside Linux browsers."
HOMEPAGE="http://fds-team.de/cms/index.html https://launchpad.net/pipelight"
SRC_URI="https://bitbucket.org/mmueller2012/pipelight/get/v${PV}.tar.gz -> ${P}.tar.gz
binary-pluginloader? ( http://repos.fds-team.de/pluginloader/v${PV}/pluginloader.tar.gz -> pluginloader-prebuilt-v${PV}.tar.gz )"
LICENSE="GPL-2 LGPL-2.1 MPL-1.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="adobereader +binary-pluginloader flash foxitpdf grandstream hikvision installation-dialogs npactivex roblox shockwave +silverlight5.1 static unity3d widevine"

DEPEND="app-arch/cabextract
	>=app-emulation/wine-1.7.21[abi_x86_32,pipelight(+)]
	x11-apps/mesa-progs"

RDEPEND="${DEPEND}"


STANDARD_PLUGINS=("silverlight5.1" "silverlight5.0" "silverlight4" "flash" "unity3d" "widevine")
ADDITIONAL_PLUGINS=("shockwave" "foxitpdf" "grandstream" "adobereader" "hikvision" "npactivex" "roblox")
ALL_PLUGINS=("${STANDARD_PLUGINS[@]}" "${ADDITIONAL_PLUGINS[@]}")

src_unpack() {
	if [ "${A}" != "" ]; then
		unpack ${A}
		# S="${WORKDIR}/${P}"
		mkdir $S
		cp -r ${WORKDIR}/mmueller2012-pipelight-*/* $S
		rm -r ${WORKDIR}/mmueller2012-pipelight-*
		cp -r ${WORKDIR}/src/* $S
		rm -r ${WORKDIR}/src
	fi
}

src_configure() {
	local myargs
	if use binary-pluginloader; then
		myargs+="--win32-prebuilt"
	elif use !binary-pluginloader; then
		if use static; then
			myargs+=" --win32-static"
		else
			myargs+=" --win32-cxx=$(/usr/bin/which wineg++)"
		fi
	fi
	if use installation-dialogs; then
		myargs+=" --show-installation-dialogs"
	fi

	# We're not using econf because this is not an autotools configure script
	# PLUGINS_DIR comes from nsplugins.eclass
	./configure \
		--prefix=/usr \
		--wine-path=/usr/bin/wine \
		--moz-plugin-path=/usr/$(get_libdir)/${PLUGINS_DIR} \
		${myargs}
}

src_install() {
	default
	# LICENSE is taken from src/linux/basicplugin.c in the pipelight source code.
	sed -n -e '/BEGIN LICENSE/,/END LICENSE/p' ${S}/src/linux/basicplugin.c >> ${S}/LICENSE
	dodoc ${S}/LICENSE debian/changelog
}

pkg_postinst() {
	einfo "Creating copies of libpipelight.so..."
	pipelight-plugin --create-mozilla-plugins

	# The following plugins are not created by "pipelight-plugin --create-mozilla-plugins" and must be "unlocked"
	for plugin in "${ADDITIONAL_PLUGINS[@]}"; do
		has $plugin ${IUSE//+/} && use $plugin && pipelight-plugin --unlock-plugin $plugin
	done

	einfo "Enabling plugins..."
	# Enable plugins based on USE flags
	for plugin in "${ALL_PLUGINS[@]}"; do
		has $plugin ${IUSE//+/} && use $plugin && pipelight-plugin --accept --enable $plugin
	done

	echo
	elog "When you first start your browser after installing Pipelight, Pipelight will    "
	elog "download and install any enabled plugins. This may take a few minutes to        "
	elog "complete.                                                                       "
	elog
	elog "Some web sites will check what operating system you are using and will not      "
	elog "function properly if they detect Linux. For these sites, you will need to       "
	elog "install and enable a user agent string editor. The user agent string            "
	elog "recommended by upstream for many Silverlight apps is                            "
	elog "Mozilla/5.0 (Windows NT 6.1; WOW64; rv:15.0) Gecko/20120427 Firefox/15.0a1      "
	elog "and for many Unity 3D apps is                                                   "
	elog "Mozilla/5.0 (Macintosh; Intel Mac OS X 10_7_3) AppleWebKit/534.55.3 (KHTML, like"
	elog " Gecko) Version/5.1.3 Safari/534.53.10                                          "
	elog "See https://answers.launchpad.net/pipelight/+faq/2351 for more information.     "
	elog
	elog "GPU acceleration is not enabled by default for all graphics cards. See          "
	elog "https://answers.launchpad.net/pipelight/+faq/2364 for more information.         "
	echo
}

pkg_prerm() {
	einfo "Disabling plugins..."
	pipelight-plugin --disable-all

	einfo "Removing copies of libpipelight.so..."
	pipelight-plugin --remove-mozilla-plugins
}