libungif-4.1.3.ebuild

libungif-4.1.3.ebuild (text/plain), 1.54 KB, created by Jung Tae-young on 2004-08-22 04:33:30 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libungif/libungif-4.1.0.1b.ebuild,v 1.14 2004/07/13 04:57:33 seemant Exp $

inherit eutils libtool

DESCRIPTION="A library for reading and writing gif images without LZW compression"
HOMEPAGE="http://prtr-13.ucsc.edu/~badger/software/libungif/index.shtml"
SRC_URI="mirror://sourceforge/libungif/${P}.tar.bz2"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~x86 ~ppc ~sparc ~mips ~alpha ~arm ~hppa ~amd64 ~ia64 ~ppc64 ~macos"
IUSE="X gif"

RDEPEND="X? ( virtual/x11 )"
DEPEND="${RDEPEND}
	>=sys-devel/autoconf-2.58"

src_compile() {
	elibtoolize || die

	local myconf
	use alpha && myconf="${myconf} --host=alpha-unknown-linux-gnu"
	econf `use_with X x` ${myconf} || die
	emake || die
}

src_install() {
	make prefix=${D}/usr install || die

	use gif && rm -rf ${D}/usr/bin

	dodoc AUTHORS BUGS COPYING ChangeLog NEWS ONEWS UNCOMPRESSED_GIF \
		README TODO doc/*.txt || die "dodoc failed"
	dohtml -r doc || die "dohtml failed"
}

pkg_postinst() {
	if use gif ; then
		einfo "You had the gif USE flag set, so it is assumed that you want"
		einfo "the binary from giflib instead.  Please make sure you have"
		einfo "giflib emerged.  Otherwise, unset the gif flag and remerge this"
	else
		einfo "You did not have the gif USE flag, so your gif binary is being"
		einfo "provided by this package.  If you would rather use the binary"
		einfo "from giflib, please set the gif USE flag, and re-emerge both"
		einfo "this and giflib"
	fi
}