net-irc/irker-2.9-ebuild

irker-2.9.ebuild (text/plain), 1.57 KB, created by Bertrand Jacquin on 2014-06-12 11:18:38 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/irker/irker-1.20.ebuild,v 1.1 2013/05/22 03:40:55 patrick Exp $

EAPI=5
PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="ssl"

inherit python-r1 systemd eutils

DESCRIPTION="Submission tools for IRC notifications"
HOMEPAGE="http://www.catb.org/esr/irker"
SRC_URI="http://www.catb.org/esr/${PN}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

# irkerhook.py and irk does not yet support >=dev-lang/python-3
REQUIRED_USE="python_targets_python2_7"

DEPEND="virtual/python-argparse[${PYTHON_USEDEP}]
	app-text/docbook-xml-dtd:4.1.2
	app-text/xmlto"

src_prepare() {
	# https://gitorious.org/irker/irker/merge_requests/25
	epatch "${FILESDIR}/${PV}-irkerhook-Register-author_name-as-author-instead-of-.patch"
	epatch "${FILESDIR}/${PV}-irkerhook-Remove-file-listing.patch"

	# Rely on systemd eclass for systemd service install
	sed -i -e "/^SYSTEMDSYSTEMUNITDIR/d" Makefile

	# Prefix support
	sed -i -e "/^ExecStart=/ s:=/:=${EROOT}:" irkerd.service
}

src_install() {
	python_install () {
		emake DESTDIR="${ED}" install

		python_doscript "${ED}/usr/bin/irkerd"
		# Not installed with the default Makefile
		python_doscript irk irkerhook.py
	}

	python_foreach_impl python_install

	newinitd "${FILESDIR}/irkerd.initd" irkerd
	newconfd "${FILESDIR}/irkerd.confd" irkerd

	systemd_dounit irkerd.service

	dodoc NEWS README hacking.txt security.txt
	dohtml irkerd.html irkerhook.html

	docinto examples
	dodoc filter-example.py filter-test.py
}