ndiswrapper .10

ndiswrapper-0.10.ebuild (text/plain), 2.49 KB, created by Saleem Abdulrasool (RETIRED) on 2004-08-21 05:20:47 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit kernel-mod

DESCRIPTION="Wrapper for using Windows drivers for some wireless cards"
HOMEPAGE="htp://ndiswrapper.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${PN}-${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"

IUSE=""
DEPEND="sys-devel/flex"
S=${WORKDIR}/${PN}-${PV}

src_unpack() {
	check_KV
	kernel-mod_getversion

	unpack ${A}

	# Kernel Path Fix
	sed -i -e "s:^KSRC.*:KSRC=${ROOT}/usr/src/linux:" \
		  -e "s:^KVERS.*:KVERS=${KV_MAJOR}${KVMINOR}:" \
		 ${S}/driver/Makefile

	if [ ${KV_MINOR} -gt 5 ] && [ ${KV_PATCH} -gt 5 ] ; then
		sed -i 's:SUBDIRS=:M=:g' ${S}/driver/Makefile
	fi
}

src_compile() {
	# Unset arch for $KV >= 2.5
	if [ ${KV_MINOR} -gt 4 ] ; then
		unset ARCH
	fi
	emake || die "Compile Failed"
}

src_install() {
	# Only copy the particular modules for current kernel
	if [ ${KV_MINOR} -gt 4 ] ; then
		MOD_SUFFIX="ko"
	else
		MOD_SUFFIX="o"
	fi

	dosbin ${S}/utils/ndiswrapper
	dosbin ${S}/utils/wlan_radio_averatec_5110hx

	dodoc ${S}/README ${S}/INSTALL ${S}/AUTHORS ${S}/ChangeLog

	insinto /lib/modules/${KV}/misc
	doins ${S}/driver/ndiswrapper.${MOD_SUFFIX}

	into /
	dosbin ${S}/utils/loadndisdriver

	insinto /etc/modules.d
	newins ${FILESDIR}/${PN}-${PVR}-modules.d ndiswrapper

	dodir /etc/ndiswrapper
}

pkg_postinst() {
	einfo "Checking kernel module dependencies"
	test -r "${ROOT}/usr/src/linux/System.map" && \
	   depmod -ae -F "${ROOT}/usr/src/linux/System.map" -b "${ROOT}" -r ${KV}
	einfo
	einfo "ndiswrapper requires .inf and .sys files from Windows(tm) driver"
	einfo "to function.  Put these files somewhere like /lib/windrivers and"
	einfo "run 'ndiswrapper -i /lib/windrivers/driver.inf'.  Once done, run"
	einfo "'modules-update'."
	einfo
	einfo "As of releases 0.9, you no longer need to call 'loadndiswrapper'"
	einfo "explicitly."
	einfo
}

pkg_config() {
	ewarn "New versions of ndiswrapper do not require you to run config"

	if [ ! -f "/etc/modules.d/ndiswrapper" ] ; then
		eerror "/etc/modules.d/ndiswrapper not found.  Please re-emerge"
		eerror "${PN} to have this file installed, then re-run this script."
		die "Driver configuration file not found!"
	fi

	# The check for pci devices is no longer needed as of version 0.9
	# Commenting it out for now, will remove later
	#I=`lspci -n | egrep 'Class (0280|0200):' |  cut -d' ' -f4`

	#if [ -z "${I}" ] ; then
	#	die "No suitable PCI devices currently found (but could be added later)"
	#fi
}