kadu-cvs-0.4.0.ebuild (New packages)

kadu-cvs-0.4.0.ebuild (text/plain), 1.68 KB, created by Lukasz on 2004-08-20 13:10:01 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit cvs eutils

DESCRIPTION="QT version of popular in Poland Gadu-Gadu IM network"
SRC_URI=""
RESTRICT="nomirror"
HOMEPAGE="http://kadu.net"
LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~x86"

IUSE="debug alsa arts esd kadu-voice nas oss spell ssl tcltk xmms"

DEPEND=">=x11-libs/qt-3.0.1
        alsa? ( media-libs/alsa-lib virtual/alsa )
        arts? ( kde-base/arts )
        esd? ( media-sound/esound )
        spell? ( app-text/aspell )
        ssl? ( dev-libs/openssl )
        tcltk? ( >=dev-lang/tcl-8.4.0 >=dev-lang/tk-8.4.0 )
        xmms? ( media-sound/xmms )" 

ECVS_SERVER="kadu.net:/usr/src/kadu"
ECVS_MODULE="kadu"

S=${WORKDIR}/${ECVS_MODULE}

module_config() {
        sed -i -r "s/(^module_${1}\\s*=\\s*).*/\\1${2}/" .config
}

src_compile() {
        local myconf

        use debug && myconf="${myconf} --enable-debug"

        # static modules (disable only, do not compile as .so)
        use ssl || module_config encryption n
        use kadu-voice || module_config voice n

        # dynamic modules
        use alsa || use oss || module_config dsp_sound n
        use arts && module_config arts_sound m
        use esd && module_config esd_sound m

        use spell && module_config spellchecker m
        use tcltk && module_config tcl_scripting m
        use xmms && module_config xmms m

        # enable modules, for which there are no USE flags
        module_config filedesc m
        module_config pcspeaker m

        econf ${myconf} || die
        emake || die
}

src_install() {
        make \
                DESTDIR=${D} \
                install || die
}