# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libsdl2/libsdl2-2.0.3.ebuild,v 1.3 2014/05/15 12:34:42 ulm Exp $

# TODO: convert FusionSound #484250

EAPI=5
inherit autotools flag-o-matic toolchain-funcs eutils multilib-minimal

MY_P=SDL2-${PV}
DESCRIPTION="Simple Direct Media Layer"
HOMEPAGE="http://www.libsdl.org"
SRC_URI="http://www.libsdl.org/release/${MY_P}.tar.gz"

LICENSE="ZLIB"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE="3dnow alsa altivec custom-cflags dbus fusionsound gles haptic +joystick mmx nas opengl oss pulseaudio +sound sse sse2 static-libs +threads tslib udev +video wayland X xinerama xscreensaver"
REQUIRED_USE="
	alsa? ( sound )
	fusionsound? ( sound )
	gles? ( video )
	nas? ( sound )
	opengl? ( video )
	pulseaudio? ( sound )
	xinerama? ( X )
	xscreensaver? ( X )"

NATIVE_RDEPEND="
	alsa? ( media-libs/alsa-lib )
	dbus? ( sys-apps/dbus )
	opengl? (
		virtual/glu
		virtual/opengl
	)
	pulseaudio? ( media-sound/pulseaudio )
	udev? ( virtual/udev )
	X? (
		x11-libs/libX11
		x11-libs/libXcursor
		x11-libs/libXext
		x11-libs/libXi
		x11-libs/libXrandr
		x11-libs/libXt
		x11-libs/libXxf86vm
		xinerama? ( x11-libs/libXinerama )
		xscreensaver? ( x11-libs/libXScrnSaver )
	)"

NATIVE_DEPEND="
	X? (
		x11-proto/xextproto
		x11-proto/xproto
	)"

COMMON_RDEPEND="
	!amd64? ( ${NATIVE_RDEPEND} )
	amd64? (
		abi_x86_64? ( ${NATIVE_RDEPEND} )
		abi_x86_32? (
			alsa? ( || (
				app-emulation/emul-linux-x86-soundlibs[alsa,development]
				media-libs/alsa-lib[abi_x86_32]
				) )
			dbus? ( || (
				app-emulation/emul-linux-x86-baselibs[development]
				sys-apps/dbus[abi_x86_32]
				) )
			opengl? ( || (
				app-emulation/emul-linux-x86-opengl[development]
				(
					virtual/glu[abi_x86_32]
					virtual/opengl[abi_x86_32]
				) ) )
			pulseaudio? ( || (
				app-emulation/emul-linux-x86-soundlibs[development]
				media-sound/pulseaudio[abi_x86_32]
				) )
			udev? ( || (
				app-emulation/emul-linux-x86-baselibs[development]
				virtual/udev[abi_x86_32]
				) )
			X? ( || (
				app-emulation/emul-linux-x86-xlibs[development]
				(
					x11-libs/libX11[abi_x86_32]
					x11-libs/libXcursor[abi_x86_32]
					x11-libs/libXext[abi_x86_32]
					x11-libs/libXi[abi_x86_32]
					x11-libs/libXrandr[abi_x86_32]
					x11-libs/libXt[abi_x86_32]
					x11-libs/libXxf86vm[abi_x86_32]
					xinerama? ( x11-libs/libXinerama[abi_x86_32] )
					xscreensaver? ( x11-libs/libXScrnSaver[abi_x86_32] )
				) ) )
			)
		)"

COMMON_DEPEND="
	!amd64? ( ${NATIVE_DEPEND} )
	amd64? (
		abi_x86_64? ( ${NATIVE_DEPEND} )
		abi_x86_32? (
			X? ( || (
				app-emulation/emul-linux-x86-xlibs[development]
				(
					x11-proto/xextproto[${MULTILIB_USEDEP}]
				    	x11-proto/xproto[${MULTILIB_USEDEP}]
				)
			) ) )
		)"

RDEPEND="
	fusionsound? ( || ( >=media-libs/FusionSound-1.1.1 >=dev-libs/DirectFB-1.7.1[fusionsound] ) )
	gles? ( media-libs/mesa[${MULTILIB_USEDEP},gles2] )
	nas? ( media-libs/nas[${MULTILIB_USEDEP}] )
	tslib? ( x11-libs/tslib[${MULTILIB_USEDEP}] )
	wayland? (
		dev-libs/wayland[${MULTILIB_USEDEP}]
		media-libs/mesa[${MULTILIB_USEDEP},wayland]
		x11-libs/libxkbcommon[${MULTILIB_USEDEP}] )
	${COMMON_RDEPEND}"

DEPEND="${RDEPEND}
	${COMMON_DEPEND}
	virtual/pkgconfig"

S=${WORKDIR}/${MY_P}

src_prepare() {
	# https://bugzilla.libsdl.org/show_bug.cgi?id=1431
	epatch "${FILESDIR}"/${P}-static-libs.patch \
		"${FILESDIR}"/${P}-gles-wayland.patch
	AT_M4DIR="/usr/share/aclocal acinclude" eautoreconf
}

multilib_src_configure() {
	use custom-cflags || strip-flags

	# sorted by `./configure --help`
	ECONF_SOURCE="${S}" econf \
		$(use_enable static-libs static) \
		$(use_enable sound audio) \
		$(use_enable video) \
		--enable-render \
		--enable-events \
		$(use_enable joystick) \
		$(use_enable haptic) \
		--enable-power \
		$(use_enable threads) \
		--enable-timers \
		--enable-file \
		--disable-loadso \
		--enable-cpuinfo \
		--enable-atomic \
		--enable-assembly \
		$(use_enable sse ssemath) \
		$(use_enable mmx) \
		$(use_enable 3dnow) \
		$(use_enable sse) \
		$(use_enable sse2) \
		$(use_enable altivec) \
		$(use_enable oss) \
		$(use_enable alsa) \
		--disable-alsa-shared \
		--disable-esd \
		$(use_enable pulseaudio) \
		--disable-pulseaudio-shared \
		--disable-arts \
		$(use_enable nas) \
		--disable-nas-shared \
		--disable-sndio \
		--disable-sndio-shared \
		$(use_enable sound diskaudio) \
		$(use_enable sound dummyaudio) \
		$(use_enable X video-x11) \
		--disable-x11-shared \
		$(use_enable wayland video-wayland) \
		--disable-wayland-shared \
		$(use_enable X video-x11-xcursor) \
		$(use_enable xinerama video-x11-xinerama) \
		$(use_enable X video-x11-xinput) \
		$(use_enable X video-x11-xrandr) \
		$(use_enable xscreensaver video-x11-scrnsaver) \
		$(use_enable X video-x11-xshape) \
		$(use_enable X video-x11-vm) \
		--disable-video-cocoa \
		--disable-video-directfb \
		$(multilib_native_use_enable fusionsound) \
		--disable-fusionsound-shared \
		$(use_enable video video-dummy) \
		$(use_enable opengl video-opengl) \
		$(use_enable gles video-opengles) \
		$(use_enable udev libudev) \
		$(use_enable dbus) \
		$(use_enable tslib input-tslib) \
		--disable-directx \
		--disable-rpath \
		--disable-render-d3d \
		$(use_with X x)
}

multilib_src_install() {
	emake DESTDIR="${D}" install
}

multilib_src_install_all() {
	use static-libs || prune_libtool_files
	dodoc {BUGS,CREDITS,README,README-SDL,README-hg,TODO,WhatsNew}.txt
}