qt4-fsarchiver-0.6.19.4.ebuild

qt4-fsarchiver-0.6.19.4.ebuild (text/plain), 1.26 KB, created by Sergey Popov on 2014-05-28 11:18:57 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

inherit eutils qt4-r2 versionator

MY_P="${PN}-$(replace_version_separator 3 '-')"
MIN_PV="$(get_version_component_range 1-3)"

DESCRIPTION="Qt4 frontend for fsarchiver"
HOMEPAGE="http://qt4-fsarchiver.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/source/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE="btrfs jfs ntfs reiser4 reiserfs sshfs xfs"

DEPEND="app-arch/xz-utils
	>=app-backup/fsarchiver-${MIN_PV}[lzma,lzo]
	dev-libs/glib:2
	dev-libs/libgcrypt:=
	dev-libs/lzo
	dev-qt/qtcore:4
	dev-qt/qtgui:4
	sys-fs/e2fsprogs
"

# Note: Samba support is broken, at least with Samba 3.*
RDEPEND="${DEPEND}
	btrfs? ( sys-fs/btrfs-progs )
	jfs? ( sys-fs/jfsutils )
	ntfs? ( sys-fs/ntfs3g[ntfsprogs] )
	reiser4? ( sys-fs/reiser4progs )
	reiserfs? ( sys-fs/reiserfsprogs )
	sshfs? ( sys-fs/sshfs-fuse )
	xfs? ( sys-fs/xfsprogs )
"

S="${WORKDIR}/${PN}"

src_prepare() {
	# fix .desktop file
	sed -i -e '/Encoding/d' starter/"${PN}".desktop || die "sed on qt4-fsarchiver.desktop failed"
	# fix icon installation location
	sed -i -e "/icon.path/s:app-install/icons:${PN}:" "${PN}.pro" || die "sed on ${PN}.pro failed"

	qt4-r2_src_prepare
}