ustr-1.0.4-r4.ebuild

ustr-1.0.4-r3.ebuild (text/plain), 1.11 KB, created by Sven Vermeulen (RETIRED) on 2014-04-21 20:10:00 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/ustr/ustr-1.0.4-r3.ebuild,v 1.4 2014/01/14 13:58:01 ago Exp $

EAPI=5

inherit multilib-build toolchain-funcs

DESCRIPTION="Low-overhead managed string library for C"
HOMEPAGE="http://www.and.org/ustr"
SRC_URI="ftp://ftp.and.org/pub/james/ustr/${PV}/${P}.tar.bz2"

LICENSE="|| ( BSD-2 MIT LGPL-2 )"
SLOT="0"
KEYWORDS="amd64 ~arm ~mips x86"
IUSE=""

DEPEND=""
RDEPEND=""

MULTILIB_WRAPPED_HEADERS=( 
	/usr/include/ustr-main.h
)

src_prepare() {
	multilib_copy_sources
}

ustr_make() {
	cd "${BUILD_DIR}" || die
	local makeopts=(
		AR="$(tc-getAR)"
		CC="$(tc-getCC)"
		CFLAGS="${CFLAGS}"
		HIDE="" 
	)
	emake "${makeopts[@]}" "$@"
}

src_compile() {
	multilib_foreach_abi ustr_make all-shared
}

multilib_src_test() {
	multilib_foreach_abi ustr_make check
}

src_install() {
	ustr_install() {
		ustr_make DESTDIR="${D}" install
		multilib_prepare_wrappers
		multilib_install_wrappers
	}
	multilib_foreach_abi ustr_install

	dodoc ChangeLog README README-DEVELOPERS AUTHORS NEWS TODO
}