# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/widelands/widelands-0.18.ebuild,v 0.1 2014/04/01 03:20:00 AlexOmskiy Exp $

EAPI=3

#     https://bugs.gentoo.org/show_bug.cgi?id=502286
#      widelands-0.18.ebuild 2014-03-03 14:24 UTC, Mario Kicherer
# AO: 2014-04-01 03:20 OMST (2014-03-31 20:20 UTC) edit:
#     correct link - http -> https
#     gcc47.patch NOT need - build 18 include this fix
#     remove *boost* strings in src_prepare() - cc1plus warnings: can't find /usr/inclide/boost-1_55 (but build without errors)
#     dev-libs/boost - need min. ver. up to 1.48 (https://wl.widelands.org/wiki/BuildingWidelands/)
#     dev-lang/lua - correct need ver. >=5.1 && <5.2 (5.2 not support - https://wl.widelands.org/wiki/BuildingWidelands/)
#     sys-libs/zlib - add 'minizip' check

inherit eutils versionator toolchain-funcs flag-o-matic cmake-utils games

MY_PV=build$(get_version_component_range 2)
MY_P=${PN}-${MY_PV}-src
DESCRIPTION="A game similar to Settlers 2"
HOMEPAGE="http://www.widelands.org/"
SRC_URI="https://launchpad.net/widelands/${MY_PV}/build-$(get_version_component_range 2)/+download/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

DEPEND="=dev-lang/lua-5.1*
	media-libs/libsdl[video]
	media-libs/sdl-image[jpeg,png]
	media-libs/sdl-mixer[vorbis]
	media-libs/sdl-gfx
	media-libs/sdl-net
	media-libs/libpng
	sys-libs/zlib[minizip]
	media-libs/glew
	media-libs/sdl-ttf
	>=dev-libs/boost-1.48"

S=${WORKDIR}/${MY_P}

CMAKE_BUILD_TYPE=Release
PREFIX=${GAMES_DATADIR}/${PN}

src_prepare() {
	sed -i -e 's:__ppc__:__PPC__:' src/s2map.cc || die
	sed -i -e 's/17/18/' CMakeLists.txt || die
}

src_configure() {
	local mycmakeargs+=(
		'-DWL_VERSION_STANDARD=true'
		"-DWL_INSTALL_PREFIX=${GAMES_PREFIX}"
		"-DWL_INSTALL_DATADIR=${GAMES_DATADIR}/${PN}"
		"-DWL_INSTALL_LOCALEDIR=${GAMES_DATADIR}/${PN}/locale"
		"-DWL_INSTALL_BINDIR=${GAMES_BINDIR}"
	)
	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
}

src_install() {
	cmake-utils_src_install
	newicon pics/wl-ico-128.png ${PN}.png || die
	make_desktop_entry ${PN} Widelands
	dodoc ChangeLog CREDITS
	prepgamesdirs
}