bitcoind-0.9.0.ebuild

bitcoind-0.9.0.ebuild (text/plain), 2.63 KB, created by Matt Whitlock on 2014-03-24 07:31:43 UTC

# Copyright 2010-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/bitcoind/bitcoind-0.8.6-r1.ebuild,v 1.1 2014/02/21 14:22:42 blueness Exp $

EAPI="4"

DB_VER="4.8"

inherit autotools bash-completion-r1 db-use eutils versionator systemd user

MyPV="${PV/_/}"
MyPN="bitcoin"
MyP="${MyPN}-${MyPV}"

DESCRIPTION="Original Bitcoin crypto-currency wallet for automated services"
HOMEPAGE="http://bitcoin.org/"
SRC_URI="https://github.com/${MyPN}/${MyPN}/archive/v${MyPV}.tar.gz -> ${MyPN}-v${PV}.tgz
"

LICENSE="MIT ISC GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="bash-completion debug examples ipv6 logrotate upnp +wallet"

RDEPEND="
	>=dev-libs/boost-1.41.0[threads(+)]
	dev-libs/leveldb
	dev-libs/openssl:0[-bindist]
	logrotate? (
		app-admin/logrotate
	)
	upnp? (
		net-libs/miniupnpc
	)
	sys-libs/db:$(db_ver_to_slot "${DB_VER}")[cxx]
"
DEPEND="${RDEPEND}
	>=app-shells/bash-4.1
	sys-apps/sed
"

S="${WORKDIR}/${MyP}"

pkg_setup() {
	local UG='bitcoin'
	enewgroup "${UG}"
	enewuser "${UG}" -1 -1 /var/lib/bitcoin "${UG}"
}

src_prepare() {
	# don't use embedded leveldb
	rm -r src/leveldb
	sed -e 's/^\(LIBLEVELDB=\).*$/\1-lleveldb/' \
		-e 's/^\(LIBMEMENV=\).*$/\1-lmemenv/' \
		-e 's/^\(AM_CONDITIONAL(\[EMBEDDED_LEVELDB\],\[\).*\(\])\)$/\1false\2/' \
		-i configure.ac

	eautoreconf
}

src_configure() {
	econf \
		--disable-silent-rules \
		$(use_enable wallet) \
		$(use_enable ipv6) \
		$(use_enable test tests) \
		--disable-hardening \
		--disable-ccache \
		$(use_enable debug) \
		$(use_with upnp miniupnpc) \
		--without-gui
}

src_compile() {
	EMBEDDED_LEVELDB=0 emake
}

src_test() {
	emake check
}

src_install() {
	dobin "src/${PN}"

	insinto /etc/bitcoin
	newins "${FILESDIR}/bitcoin.conf" bitcoin.conf
	fowners bitcoin:bitcoin /etc/bitcoin/bitcoin.conf
	fperms 600 /etc/bitcoin/bitcoin.conf

	newconfd "${FILESDIR}/bitcoin.confd" "${PN}"
	newinitd "${FILESDIR}/bitcoin.initd-r1" "${PN}"
	systemd_dounit "${FILESDIR}/bitcoind.service"

	keepdir /var/lib/bitcoin/.bitcoin
	fperms 700 /var/lib/bitcoin
	fowners bitcoin:bitcoin /var/lib/bitcoin/
	fowners bitcoin:bitcoin /var/lib/bitcoin/.bitcoin
	dosym /etc/bitcoin/bitcoin.conf /var/lib/bitcoin/.bitcoin/bitcoin.conf

	dodoc doc/README.md doc/release-notes.md
	doman contrib/debian/manpages/{bitcoind.1,bitcoin.conf.5}

	if use bash-completion; then
		newbashcomp "contrib/${PN}.bash-completion" "${PN}"
	fi

	if use examples; then
		docinto examples
		dodoc -r contrib/{README.md,bitrpc,pyminer,spendfrom,linearize,qos}
	fi

	if use logrotate; then
		insinto /etc/logrotate.d
		newins "${FILESDIR}/bitcoind.logrotate" bitcoind
	fi
}